topic Re: Display in log window in SAS Programming

Display in log window

BrahmanandaRao — Fri, 25 Oct 2019 16:07:06 GMT

Hi Experts Good Evening

I am want output like below format in log window

Total_Female=9

Total_Male=10

/*How to find total count with Gender_wise*/

data ds;
set sashelp.class;
run;

proc sort data=ds;
by sex;
run;

data sex_count(keep=sex Gender_wise_total_count);
set ds ;
by sex ;
if first.sex then Gender_wise_total_count=0;
Gender_wise_total_count+1;
if last.sex ;
put  Total_Gender_wise_total_count=Gender_wise_total_count;
run;

Re: Display in log window

PeterClemmensen — Fri, 25 Oct 2019 16:15:33 GMT

Here is one way

proc sort data=sashelp.class out=ds;
   by sex;
run;

data _null_;
   do total=1 by 1 until (last.sex);
      set ds;
      by sex;
   end;
   put "Total_"sex"=" total;
run;

Result in log:

Total_F =9
Total_M =10

Re: Display in log window

Kurt_Bremser — Fri, 25 Oct 2019 16:18:13 GMT

Different approach using proc freq:

proc freq data=sashelp.class;
tables sex / out=sum (keep=sex count);
run;

proc format;
value $sexfmt
  "F" = "Female"
  "M" = "Male"
;
run;

data _null_;
set sum;
outstring = cats(catx(" ",'Total',put(sex,$sexfmt.)),"=",count);
put outstring;
run;

Re: Display in log window

BrahmanandaRao — Fri, 25 Oct 2019 16:23:21 GMT

HI Draycut

Brilliant code Thank you very much

Re: Display in log window

BrahmanandaRao — Fri, 25 Oct 2019 16:24:49 GMT

Hi KurtBremser

Brilliant code Thank you very much sir