topic Re: Can I run a specific part of code without using macro? in SAS Programming

Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 07:56:36 GMT

Dear All, I was wondering if I can repeat a certain part of my SAS code, as described below. Is there something like goto statement I can make use of? To be clear, I don't want to make a formal macro code for this, but I want to repeat the MAIN STATEMENTS by using %let statement.

MAIN SAS STATEMENTS (including %let var=;) from line 1 to 100

%let var= abc;

Run the MAIN STATEMENTS.

%let var= def;

Run the MAIN STATEMENTS.

%let var= ghi;

Run the MAIN STATEMENTS.

So, the code would be less than 110 lines. Hope that there is such a way to implement this. Of course, I now I can use the macro, but then all statements in the macro have the same color, so it's not so convenient to debug. This is perhaps my taste, but I really prefer this way. In addition, I have to revise my code from time to time. This way makes it easier for me. Thanks in advance.

Re: Can I run a specific part of code without using macro?

SASKiwi — Fri, 11 Oct 2019 08:10:19 GMT

Store your MAIN statements in a separate SAS program called perhaps MAIN.sas then do this:

%let var= abc;
%include 'MAIN.sas';

%let var= def;
%include 'MAIN.sas';

%let var= ghi;
%include 'MAIN.sas';

Re: Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 12:39:49 GMT

Thanks. But can it be possible within one SAS code?
Second, do you know how I can let my SAS run just a part of the external code file (rather than the entire code)?

Re: Can I run a specific part of code without using macro?

PaigeMiller — Fri, 11 Oct 2019 13:22:10 GMT

@braam wrote:
Thanks. But can it be possible within one SAS code?

Do you mean you don't want MAIN.SAS as a separate file and then the code with %include in a separate file? Then I don't think this is possible without using macros; or if whatever you have in MAIN.SAS is just purely data step code in a single data step, with no PROCs, then you could do this via the LINK statement, which creates a "subroutine" inside the data step that can be used many times within the same data step.

Second, do you know how I can let my SAS run just a part of the external code file (rather than the entire code)?

Macros

Of course, I now I can use the macro, but then all statements in the macro have the same color, so it's not so convenient to debug.

The advice is ALWAYS to get the code working without macros and without macros variables for one or two situations, then the debugging features of SAS on the base code work fine. Then you can turn it into a macro with much more ease, because you won't have to be debugging the underlying code.

Re: Can I run a specific part of code without using macro?

Kurt_Bremser — Fri, 11 Oct 2019 13:03:10 GMT

@braam wrote:
Thanks. But can it be possible within one SAS code?
Second, do you know how I can let my SAS run just a part of the external code file (rather than the entire code)?

This all falls into the realm of "dynamic code", and that's what the macro language is for.

Re: Can I run a specific part of code without using macro?

PeterClemmensen — Fri, 11 Oct 2019 13:24:48 GMT

You can not submit specific lines of code from external files using %include. I believe you can do something like this, though I have not tested it

options spool;

%let var= abc;
data test_&var.;
    a=1;
run;

%let var=def;
%include 4-6;

%let var=ghi;
%include 4-6;

Re: Can I run a specific part of code without using macro?

PaigeMiller — Fri, 11 Oct 2019 13:21:18 GMT

@PeterClemmensen wrote:

Yout can not submit specific lines of code from external files using %include. I believe you can do something like this, though I have not tested it
options spool;

%let var= abc;
data test_&var.;
    a=1;
run;

%let var=def;
%include 4-6;

%let var=ghi;
%include 4-6;

I suppose this works, but it's not very clear code to anyone looking at this, it reminds me of Excel references; and don't ever change the code so that lines 4-6 move up or down in the code, because then you also have to change all of the %include statements.

Re: Can I run a specific part of code without using macro?

Tom — Fri, 11 Oct 2019 13:18:39 GMT

Why do you care what colors the editor is using? SAS does not see the colors. Just the text.

Re: Can I run a specific part of code without using macro?

PeterClemmensen — Fri, 11 Oct 2019 13:22:10 GMT

@PaigeMiller I agree. A macro or Call execute logic is the answer here, this just popped up in my head since @braam asked if it is possible to execute parts of - and not the entire code from an external .sas file 🙂

Re: Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 13:35:05 GMT

@PeterClemmensen Thanks. I actually tried code like this. But the thing is that the numbers following %include (4-6 in your example) are the line numbers in the log window, not in the code file, if I understood correctly. I'll try this way a little further. By the way, what do you mean by call execute? Could you give a little more hint?

@PaigeMiller You are right. So, users have to be careful with that. Thanks for your answer as well.

Re: Can I run a specific part of code without using macro?

PeterClemmensen — Fri, 11 Oct 2019 13:40:16 GMT

Just an alternative to creating dynamic code. Like this

data _null_;
    do suffix='abc', 'def', 'ghi';
        call execute(cat(
           "data ", suffix, ";
               a=1;
           run;"
        ));
    end;
run;

You can read more in the article CALL EXECUTE made easy for SAS data-driven programming

Re: Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 14:13:33 GMT

Thanks. The link looks very helpful to me. I'll read this carefully today.

Fortunately, I've got a hint from one of the old posts: https://communities.sas.com/t5/General-SAS-Programming/Recalling-only-a-portion-of-data-lines-from-another-program/td-p/251212

data _null_;
      infile '"C:\PATH\FILE1.sas"' firstobs= 108 obs=200;
      file '"C:\PATH\FILE2.sas"';
      input;
      put _infile_;
      run;

Based on what I found in the posting, I made this code, which works for me. In the posting, one mentioned that firstobs option can be replaced by something else more intuitive, user-friendly (A similar issue has already been discussed in this thread).

Perhaps I can add "BEGINNING" and "ENDING" tags in my file1 to indicate the first line and the ending line of the part I would like to take in file2. I'm just wondering if you know any way to solve this issue. Thanks again for your advice.

Re: Can I run a specific part of code without using macro?

Kurt_Bremser — Fri, 11 Oct 2019 14:30:27 GMT

Add comment lines to your code that mark starts and ends. Then you can skip lines (no put) until a certain start comment is detected, and write lines until the corresponding end comment is found.

Re: Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 17:08:55 GMT

Sorry but, I don't know how to implement what you desribed...(skipping until the start comment is detected...) Could you please give me some hints or example codes?

Re: Can I run a specific part of code without using macro?

Kurt_Bremser — Fri, 11 Oct 2019 17:25:27 GMT

Suppose you have a main.sas program like this:

/* some steps */

/* start block 1 */

/* steps you want to selectively run */

/* end block 1 */

/* rest of code */

now run this step:

data _null_;
infile "main.sas";
file "select.sas";
retain flag 0;
input;
if index(_infile_,"start block 1") then flag = 1;
if index(_infile_,"end block 1") then flag = 0;
if flag then put _infile_;
run;

%include "select.sas";

Re: Can I run a specific part of code without using macro?

braam — Fri, 11 Oct 2019 19:59:39 GMT

That works for me perfectly. Thanks a lot.

Re: Can I run a specific part of code without using macro?

hashman — Fri, 11 Oct 2019 21:28:28 GMT

@braam:

In the SAS days of yore, this kind of functionality was served with so-called old-style macros. Basically, they work similarly to %include, but instead of pointing to an external program file, you call a piece of the program identified by the old-style macro name. Needless to say, these things still work (note that the old-style macro names are limited to 8 characters, plus there're other limitations). For example:

option macrogen ;                                                                                                                       
                                                                                                                                        
macro MAIN ;                                                                                                                            
data new ;                                                                                                                              
  set &data ;                                                                                                                           
run ;                                                                                                                                   
%                                                                                                                                       
                                                                                                                                        
%let data = sashelp.class ;                                                                                                             
                                                                                                                                        
MAIN                                                                                                                                    
                                                                                                                                        
%let data = sashelp.cars ;                                                                                                              
                                                                                                                                        
MAIN

Here's what you see in the log:

1820  macro MAIN ;
1821  data new ;
1822    set &data ;
1823  run ;
1824  %
1825
1826  %let data = sashelp.class ;
1827
1828  MAIN
NOTE: The old-style macro MAIN is beginning resolution.
1829 + ;
1830 +data new ;
1831 +  set &data ;
1832 +run ;

NOTE: There were 19 observations read from the data set SASHELP.CLASS.
NOTE: The data set WORK.NEW has 19 observations and 5 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.01 seconds

NOTE: The old-style macro MAIN is ending resolution.
1833
1834  %let data = sashelp.cars ;
1835
1836  MAIN
NOTE: The old-style macro MAIN is beginning resolution.
1837 + ;
1838 +data new ;
1839 +  set &data ;
1840 +run ;

NOTE: There were 428 observations read from the data set SASHELP.CARS.
NOTE: The data set WORK.NEW has 428 observations and 15 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds
      cpu time            0.01 seconds

NOTE: The old-style macro MAIN is ending resolution.

he MACROGEN option causes the appearance of the "+" lines in the log; basically, it's like using SOURCE2 with %include. Its advantage over MPRINT is that if you have a run-time error, the log will point to the actual line where it occurred rather than at the line where the macro was invoked (as with the current-style macros). Another advantage is that DATA steps with CARDS (LINES, DATALINES) are also acceptable. Essentially an old-style macro is nothing but copy-and-paste.

Kind regards

Paul D.

Re: Can I run a specific part of code without using macro?

SASKiwi — Fri, 11 Oct 2019 21:55:28 GMT

@hashman - Gee, this is bringing back memories!

Re: Can I run a specific part of code without using macro?

hashman — Sat, 12 Oct 2019 01:09:20 GMT

@SASKiwi - Sure does! But am not sure at all how many folks here percentage-wise can still claim it.