topic Re: SGPLOT KEYLEGEND Problem in SAS Programming

SGPLOT KEYLEGEND Problem

Junyong — Thu, 10 Oct 2019 15:19:57 GMT

I have the following data.

data have;
do groupname="Group 1","Group 2","Group 3";
do i=1 to 100;
x=2*substr(groupname,6)+rannor(1);
output;
end;
end;
run;

As I want to draw a histogram of three groups, I did the following.

proc sgplot;
histogram x/group=groupname transparency=0.3333;
density x/group=groupname type=kernel;
run;

Here's the outcome.

I tried to erase the "groupname" inside the bottom legend box, so used KEYLEGEND as follows.

proc sgplot;
histogram x/group=groupname transparency=0.3333;
density x/group=groupname type=kernel;
keylegend/title="";
run;

And it seems KEYLEGEND unties the items and the outcome repeats these groups twice.

How can I suppress the "groupname" here while avoiding this untying behavior? Thanks for your help.

Re: SGPLOT KEYLEGEND Problem

PeterClemmensen — Thu, 10 Oct 2019 15:22:34 GMT

What version of SAS do you use?

Re: SGPLOT KEYLEGEND Problem

Junyong — Thu, 10 Oct 2019 15:37:43 GMT

It's 9.4 TS1M5. I found the same at https://odamid.oda.sas.com/ too.

Re: SGPLOT KEYLEGEND Problem

ballardw — Thu, 10 Oct 2019 15:46:46 GMT

You are getting two sets in the legend because the default is to provide a legend for each plot.

You can request which items to include in the legend by listing the names in the Keylegend statement. Which means that you use the options on the histogram and density statements to name their legend entries.

Example below should only show the legend for the histogram. Change 'Hist' to 'Dens' to show the density legend.

proc sgplot;
   histogram x/group=groupname transparency=0.3333 name='Hist';
   density x/group=groupname type=kernel name='Dens';
   keylegend  'Hist' /  title=""  ;
run;