topic deleting observations with several variables missing in SAS Programming

deleting observations with several variables missing

catch18 — Wed, 09 Oct 2019 03:22:37 GMT

Hi,

I have to delete observations with more than 10 variables recorded as 0. I have used macros so far but it is not working and I'm not familiar with array. Each observation has 60 variables. Any suggestions would be very much appreciated. Thanks.

Re: deleting observations with several variables missing

catch18 — Wed, 09 Oct 2019 03:23:36 GMT

I should add that all the variables are numeric. Thanks

Re: deleting observations with several variables missing

Reeza — Wed, 09 Oct 2019 03:38:22 GMT

If all variables are numeric you can use an array very simply.

data want;
set have;

array myVars (*) _numeric_ ; *uses ALL numeric variables;
*array myVars (*) list of variables;

if nmiss(of myvars(*)) >= 10 then delete;

run;

Here is a reference that illustrates how to refer to variables and datasets in a short cut list:
https://blogs.sas.com/content/iml/2018/05/29/6-easy-ways-to-specify-a-list-of-variables-in-sas.html

And here's a tutorial on arrays.

https://stats.idre.ucla.edu/sas/seminars/sas-arrays/

@catch18 wrote:

Hi,

I have to delete observations with more than 10 variables recorded as 0. I have used macros so far but it is not working and I'm not familiar with array. Each observation has 60 variables. Any suggestions would be very much appreciated. Thanks.

Re: deleting observations with several variables missing

catch18 — Wed, 09 Oct 2019 03:54:55 GMT

Thanks for the links and the suggestion but the code hasn't made a difference so far. I only changed data want, set have.

Re: deleting observations with several variables missing

Patrick — Wed, 09 Oct 2019 05:56:34 GMT

@catch18 wrote:

Thanks for the links and the suggestion but the code hasn't made a difference so far. I only changed data want, set have.

Below code should work for counting zero's. What @Reeza posted would work for missings.

data have;
  array nvars {20} 8 (20*0);
  do i=1 to 20;
    nvars[i]=i;
    output;
  end;
  stop;
run;

data want;
  set have;
  array myVars _numeric_;
  _n_=0;
  do over myVars;
    if myVars=0 then 
      do;
        _n_+1;
        if _n_>=10 then delete;
      end;
  end;
run;

proc print;
run;

Re: deleting observations with several variables missing

catch18 — Wed, 09 Oct 2019 06:03:49 GMT

Thanks, but could you please explain this step: array nvars {20} 8 (20*0);?

Re: deleting observations with several variables missing

Patrick — Wed, 09 Oct 2019 06:09:01 GMT

@catch18 wrote:

Thanks, but could you please explain this step: array nvars {20} 8 (20*0);?

This is just creating sample data as you haven't posted any. It creates 20 numerical variables nvars1-nvars20 populated with an initial value of 0.

The array statement is documented here or start with the tutorial @Reeza already shared with you.

Re: deleting observations with several variables missing

catch18 — Wed, 09 Oct 2019 06:15:56 GMT

It definitely worked without the first data step! Many thanks!