topic Re: how do I find the minimizer value in non linear optimization problem? in SAS Programming

how do I find the minimizer value in non linear optimization problem?

rohailk — Sun, 06 Oct 2019 21:53:00 GMT

Hi,

I am trying to solve the following question

I have written the following code for this

proc optmodel;
var x, y,z;
min f = 4*(x^2+y-z)^2 + 10;
/* starting point */
   x = 1;
   y = 1;
   z=1;
solve; 
print x y z x.dual y.dual z.dual;
quit;

Now if P is the descent direction of f at Xo then

I need to find the minimizer Aplha for this problem

I mean to say that I am trying to solve this question:

I dont see Alpha in the output.

Please can someone help me find the value of Alpha which is the minimizer

thanks

Re: how do I find the minimizer value in non linear optimization problem?

Ksharp — Mon, 07 Oct 2019 11:34:47 GMT

Post it at OR forum . @RobPratt is there .

Re: how do I find the minimizer value in non linear optimization problem?

RobPratt — Mon, 07 Oct 2019 15:40:18 GMT

To find the descent direction from the initial point, you need to fix the values of the variables and then take the negative gradient. To find the best step size alpha in that direction, you can solve an auxiliary one-variable problem. The following code implements these ideas, where I have renamed the original variables x[1], x[2], and x[3].

proc optmodel;
   num n = 3;
   var x {1..n} init 1;
   min f = 4*(x[1]^2+x[2]-x[3])^2 + 10;
   fix x;
   solve; 
   print x x.dual;

   num p {1..n};
   for {j in 1..n} p[j] = -x[j].dual;
   var alpha >= 0;
   min g = 4*((x[1]+alpha*p[1])^2+(x[2]+alpha*p[2])-(x[3]+alpha*p[3]))^2 + 10;
   solve; 
   print alpha;
quit;

One more question please Re: how do I find the minimizer value in non linear optimization problem?

rohailk — Tue, 08 Oct 2019 05:10:11 GMT

thank you so much for your answer . @RobPratt

Just one more question.I am trying to re write your program for the following problem.

 min f = (x[1]-2)**4 + (x[1]-2*x[2])**2;

Sorry I am new to sas .Please can you help me write the same code as that in your answer for this new problem to calculate alpha.I tried but each time I tried I got alpah=0 and a an error message also

Thanks

Re: One more question please Re: how do I find the minimizer value in non linear optimization probl

RobPratt — Fri, 11 Oct 2019 14:32:02 GMT

Here's how I would do it:

proc optmodel;
   num n = 2;
   var x {1..n};
   min f = (x[1]-2)**4 + (x[1]-2*x[2])**2;
   fix x[1] = 0;
   fix x[2] = 3;
   solve; 
   print x x.dual;

   num p {1..n};
   for {j in 1..n} p[j] = -x[j].dual;
   var alpha >= 0;
   min g = (x[1]+alpha*p[1]-2)**4 + (x[1]+alpha*p[1]-2*(x[2]+alpha*p[2]))**2;
   solve;
   print alpha;
quit;

Re: One more question please Re: how do I find the minimizer value in non linear optimization probl

rohailk — Fri, 11 Oct 2019 17:46:23 GMT

thank you so much