topic Re: Using today's date to target a .xls file from webpage in SAS Programming

Using today's date to target a .xls file from webpage

pants4 — Tue, 31 Jul 2012 04:19:43 GMT

I'm trying to import a .xls file that is posted daily as part of an automated procedure. A sample path is shown below:

https://www.xyzqrs.com/Reports/20120730_ex.xls

The following code works:

filename website http "https://www.xyzqrs.com/Reports/20120730_ex.xls" debug;

data file;
n=-1;
infile website nbyte=n length=len;
input;
file "20120730_ex.xls";
put _infile_ $varying32767. len;
run;

PROC IMPORT OUT=WORK.excelfile DATAFILE="20120730_ex.xls" DBMS=EXCEL REPLACE;
GETNAMES=NO;
MIXED=YES;
SCANTEXT=YES;
USEDATE=YES;
SCANTIME=YES;
RUN;

I want to somehow use a macro variable or some other method to edit red text above, so everyday when this runs, it grabs the most recent file. I've tried to use macro variables to pass in the date, but it doesn't read it correctly in the program. I've tried researching the answer online, but no luck up to this point. Any help is appreciated...Thanks!

Re: Using today's date to target a .xls file from webpage

art297 — Tue, 31 Jul 2012 04:49:50 GMT

I can't test this at the moment, but think it is either correct or close enough that you should be able to get it to work:

%let fname=%sysfunc(putn(%sysfunc(today()),yymmddN8.));
filename website http "https://www.xyzqrs.com/Reports/&fname._ex.xls" debug;

data file;
n=-1;
infile website nbyte=n length=len;
input;
file "&fname._ex.xls";
put _infile_ $varying32767. len;
run;

PROC IMPORT OUT=WORK.excelfile DATAFILE="&fname._ex.xls" DBMS=EXCEL REPLACE;
GETNAMES=NO;
MIXED=YES;
SCANTEXT=YES;
USEDATE=YES;
SCANTIME=YES;
RUN;

Re: Using today's date to target a .xls file from webpage

pants4 — Tue, 31 Jul 2012 05:10:59 GMT

Worked like a charm. Thanks for the quick reply and fix