topic Re: Creating a variable with multiple values in SAS Programming

Creating a variable with multiple values

cool1993 — Thu, 26 Sep 2019 11:18:55 GMT

Hello.

I want to make a variable to have multiple inputs.

The data and the desired results are as follows:

Data

NAME	YEAR	Char
JOY	2011	AA
JOY	2011	BB
JOY	2012	AA
JOY	2012	BB
JOY	2012	CC

Desired result

NAME	YEAR	Find
JOY	2011	AA, BB
JOY	2012	AA, BB, CC

If you know how, please help me.

Re: Creating a variable with multiple values

PeterClemmensen — Thu, 26 Sep 2019 11:27:39 GMT

data have;
input NAME $ YEAR Char $;
datalines;
JOY 2011 AA
JOY 2011 BB
JOY 2012 AA
JOY 2012 BB
JOY 2012 CC
;

data want(drop=Char);
    do until (last.year);
        set have;
        length Find $100;
        by year;
        Find=catx(', ', Find, Char);
    end;
run;

Result:

Name Year   Find
JOY  2011   AA, BB
JOY  2012   AA, BB, CC

Re: Creating a variable with multiple values

Ksharp — Thu, 26 Sep 2019 11:29:10 GMT

data have;
infile cards expandtabs truncover;
input NAME $ YEAR	Char $;
cards;
JOY	2011	AA
JOY	2011	BB
JOY	2012	AA
JOY	2012	BB
JOY	2012	CC
;

data want;
 do until(last.year);
  set have;
  by name year;
  length want $ 800;
  want=catx(',',want,char);
 end;
 drop char;
run;

Re: Creating a variable with multiple values

Kurt_Bremser — Thu, 26 Sep 2019 11:30:48 GMT

Use by-group processing and a retained variable:

data have;
input NAME $ YEAR Char $;
datalines;
JOY 2011 AA
JOY 2011 BB
JOY 2012 AA
JOY 2012 BB
JOY 2012 CC
;

data want;
set have;
by name year;
length chars $20;
retain chars;
if first.year
then chars = char;
else chars = catx(',',chars,char);
if last.year;
drop char;
run;

proc print data=want noobs;
run;

Result:

NAME	YEAR	chars
JOY	2011	AA,BB
JOY	2012	AA,BB,CC