topic Re: Session compiled macro catalog in SAS Programming

Session compiled macro catalog

Jakkas — Tue, 10 Sep 2013 17:41:07 GMT

How can I see information about all session compiled macros?

Thanks!!

Re: Session compiled macro catalog

jakarman — Tue, 10 Sep 2013 19:17:41 GMT

If you just want to know the names of the automatic compiled ones ... look in the catalog present in saswork

Re: Session compiled macro catalog

Jakkas — Tue, 10 Sep 2013 19:55:12 GMT

Thanks. I am looking for user compiled macros.

Re: Session compiled macro catalog

jakarman — Tue, 10 Sep 2013 20:01:47 GMT

Please explain me the difference or your intention of your question.

Macros can be pre-compiled by users and by options getting used.
Autocall macros being used user/session are getting compiled and by that the compiled version gets stored in that catalog.

Manually compiling of macros is also possible by using the %inc statement or defining them in-stream in other code.

Re: Session compiled macro catalog

data_null__ — Tue, 10 Sep 2013 20:47:59 GMT

PROC CATALOG

Re: Session compiled macro catalog

Patrick — Tue, 10 Sep 2013 22:55:03 GMT

If not explicitly defined different then session specific macros get compiled into a catalog in WORK. I believe the catalog name is sasmacr. Use Proc Catalog to list it's content.

I believe there is also a sashelp table listing compiled macros.

Re: Session compiled macro catalog

Tom — Tue, 10 Sep 2013 23:19:47 GMT

data macros;

set sashelp.vcatalg;

where libname='WORK' and memname='SASMACR'

and memtype='CATALOG' and objtype='MACRO';

run;

Re: Session compiled macro catalog

Jakkas — Wed, 11 Sep 2013 16:14:57 GMT

The following doesn't work. It gives an error saying wor.SASMACR doesn't exist. So I don't see a way to see the session compiled macros using PROC CATALOG.

Proc catalog cat=work.sasmacr;

contents out=temp;

run;

SASHELP.VCATALG Does show me all the session compiled macros. But I am not able to delete a macro from it. So how would you delete a session compiled macro from work.SASMACR? If I could get to the catalog from PROC Catalog I could use delete statement.

Re: Session compiled macro catalog

Tom — Wed, 11 Sep 2013 18:37:06 GMT

Depends on what you mean by "session". When you run SAS directly from the operating system it uses WORK.SASMACR catalog. But a few years ago when playing with Enterprise Guide I found it was using WORK.SASMAC1 instead.

Try this little program to take a snapshot from the metadata before and after compiling a macro and see what changes.

proc sql ;

create table before as

select libname,memname,objname,created from dictionary.catalogs

where objtype='MACRO'

order by 1,2,3

;

%macro test2; %mend ;

create table after as

select libname,memname,objname,created from dictionary.catalogs

where objtype='MACRO'

order by 1,2,3

;

quit;

proc compare data=before compare=after listall ;

id libname memname objname;

run;

36360 - How to determine whether a macro exists within a SAS session

Re: Session compiled macro catalog

Jakkas — Wed, 11 Sep 2013 19:17:59 GMT

Thanks Tom. So what I was missing was that it is called SASMAC1 instead of SASMACR. Here is how I am able to uncompile a macro.

%Macro MyMacro1;
%put &SYSMACRONAME. says Shazzam;
%Mend;

%myMacro1 /* Runs fine. */

Proc catalog cat=work.SASMAC1;

contents out=temp; /* Shows that myMacro1 is in the work macro catalog. */
Run;

Proc catalog cat=Work.SASMAC1;
delete MyMacro1 (ET=MACRO); /* Deletes myMacro1 from work macro catalog. */
Run;

%myMacro1 /* Error. the macro definition is no longer available. */