topic Re: Create Observation for a missing value. in SAS Programming

Create Observation for a missing value.

Babloo — Wed, 11 Sep 2019 09:54:05 GMT

Appericiate if someone of you help me tweak the code below to create missing value for ENITY_NM (character variable) if there is 0 obersvation in the Input dataset 'dis_entity_id'

752        /*extract and append ENTY_NMs based on Entity_ID*/
753        
754        data reqd_vars (drop=ENTITY_ID);
755        	set dis_entity_id end=last_record;
756        	by ENTITY_ID;
757        	length ENTY_NM $50;
758        	retain ENTY_NM;
759        	if first.ENTITY_ID then
760        	ENTY_NM=catx('/',ENTY_NM,put(ENTITY_ID, $ENTITY.));
761        	if last_record then
762        		output;
763        run;

NOTE: There were 0 observations read from the data set WORK.DIS_ENTITY_ID.
NOTE: The data set WORK.REQD_VARS has 0 observations and 1 variables.
NOTE: DATA statement used (Total process time):
      real time           0.00 seconds

Desired Output if the source dataset 'dis_entity_id' has 0 bbservation,

ENTY_NM

" "

Re: Create Observation for a missing value.

VinitvictorCorr — Wed, 11 Sep 2019 10:04:44 GMT

one suggestion, not sure if it would work but in the second if statement do the below.

if last_record then do;
enity_nm="";
output;
end;

Re: Create Observation for a missing value.

VinitvictorCorr — Wed, 11 Sep 2019 10:05:52 GMT

you might get the observations with missing character values

Re: Create Observation for a missing value.

Babloo — Wed, 11 Sep 2019 10:23:44 GMT

I tried and it didn't work as I got 0 observation

Re: Create Observation for a missing value.

novinosrin — Wed, 11 Sep 2019 11:47:13 GMT

Hi @Babloo If you have 0 obs in your dataset and want an observation with missing values, here is one easy way

data want;
if 0 then set have;
call missing(of _all_);
output;
stop;
run;

Re: Create Observation for a missing value.

Babloo — Wed, 11 Sep 2019 12:46:38 GMT

I tried the code as follows and ended up with error. If there is Observation in the dataset then I want to get that value in 'vars' dataset.

2859       data vars;
2860       if 0 then set dis_entity_id;
2861       call missing(of _all_);
2862       else set dis_entity_id;
           ____
           160
ERROR 160-185: No matching IF-THEN clause.

2863       output;
2864       stop;
2865       run;

NOTE: The SAS System stopped processing this step because of errors.

Re: Create Observation for a missing value.

novinosrin — Wed, 11 Sep 2019 13:00:10 GMT

Hi @Babloo Oh that logic is solely for zero obs dataset and please do not confuse and modify the logic like you did. Please follow the code below and see if you understand. I have written some comments to help you.


%macro check_and_do;
/*Get the number of obs in macro var N*/
proc sql noprint;
select nobs into :n trimmed
from dictionary.tables 
where libname='WORK' and memname='HAVE';
quit;

%put &=n;/*N is the number of obs in HAVE*/
/*Check if N>0*/
%if &n>0 %then %do;
 data want;
 set have;
 run;
%else %do;
/*If n=0 then do the below*/
 data want;
 if 0 then set have;
 call missing(of _all);
 output;
 stop;
 run;
 %end;
%mend check_and_do;

%check_and_do

Re: Create Observation for a missing value.

Babloo — Thu, 12 Sep 2019 06:45:48 GMT

Am I doing something wrong?

26         %macro check_and_do;
27         /*Get the number of obs in macro var N*/
28         proc sql noprint;
29         create table have as select nobs into :n
30         from sashelp.class;
31         quit;
32         
33         %put &=n;/*N is the number of obs in HAVE*/
34         /*Check if N>0*/
35         %if &n>0 %then %do;
36          data want;
37          set have;
38          run;
39         %else %do;
ERROR: There is no matching %IF statement for the %ELSE.
ERROR: A dummy macro will be compiled.
40         /*If n=0 then do the below*/
41          data want;
42          if 0 then set have;
43          call missing(of _all);
44          output;
45          stop;
46          run;
47          %end;
48         %mend check_and_do;
49         
50         %check_and_do
WARNING: Apparent invocation of macro CHECK_AND_DO not resolved.

Re: Create Observation for a missing value.

novinosrin — Thu, 12 Sep 2019 14:54:30 GMT

Hi @Babloo I missed to add a %end . Sorry about that. Here is a tested sample

data sample;
set sashelp.class(obs=0);
run;


%macro check_and_do(dsn=SAMPLE);
/*Get the number of obs in macro var N*/
proc sql noprint;
select nobs into :n trimmed
from dictionary.tables 
where libname='WORK' and memname="&dsn";
quit;

%put &=n;/*N is the number of obs in HAVE*/
/*Check if N>0*/
%if &n>0 %then %do;
 data want;
 set &dsn;
 run;
 %end;
%else %do;
/*If n=0 then do the below*/
 data want;
 if 0 then set &dsn;
 call missing(of _all_);
 output;
 stop;
 run;
 %end;
%mend check_and_do;

%check_and_do