topic Re: Export as a text file in SAS Programming

Export as a text file

laksh_05 — Thu, 22 Aug 2019 07:37:03 GMT

Hi,

I want to export a text file from sas which sums up certain variables of a dataset and exports it out in a format given below.

For example : balance_lc is a variable in a dataset and 9789919877.97 is the sum of this variable for all the rows in the dataset.

can you please help me in how do i sum it up and export as text file in the format given below.

Re: Export as a text file

Kurt_Bremser — Thu, 22 Aug 2019 07:59:56 GMT

See this example, using sashelp.class:

proc summary data=sashelp.class;
var age height weight;
output out=class_sum (drop=_type_ rename=(_freq_=Rowcount)) sum=;
run;

data _null_;
set class_sum;
file '$HOME/out.txt';
array vars _numeric_;
do i = 1 to dim(vars);
  name = vname(vars{i});
  value = vars{i};
  put name "= " value;
end;
run;

The resulting text file:

Rowcount = 19
Age = 253
Height = 1184.4
Weight = 1900.5

Edit: added rowcount

Re: Export as a text file

laksh_05 — Thu, 22 Aug 2019 08:21:15 GMT

Thanks a lot. Is there a way i can format just the sum of the variables to 18.6

Re: Export as a text file

Kurt_Bremser — Thu, 22 Aug 2019 08:24:00 GMT

Expand the code to use a dynamic format:

data _null_;
set class_sum;
file '$HOME/out.txt';
array vars _numeric_;
do i = 1 to dim(vars);
  name = vname(vars{i});
  if name = 'Rowcount'
  then format = 'best.';
  else format = '18.6';
  value = strip(putn(vars{i},format));
  put name "= " value;
end;
run;

Re: Export as a text file

ballardw — Thu, 22 Aug 2019 15:23:10 GMT

@Kurt_Bremser wrote:

Expand the code to use a dynamic format:

data _null_;
set class_sum;
file '$HOME/out.txt';
array vars _numeric_;
do i = 1 to dim(vars);
  name = vname(vars{i});
  if name = 'Rowcount'
  then format = 'best.';
  else format = '18.6';
  value = strip(putn(vars{i},format));
  put name "= " value;
end;
run;

And for slightly prettier output if this is read by people, try :

put name @25 "= " value;

as an alternative to the above put statement.