topic Re: Scan or Find or Count option in SAS Programming

Scan or Find or Count option

stancemcgraw — Tue, 06 Aug 2019 21:46:40 GMT

I'm trying to create a variable that counts when a procedure says "CT", "XRAY", "MRI" and call it Imaging and then so on and so forth for other types of variable groups I want. Is there a scan or count or find function that would work in this scenario?

data have:

studynum procs

1 xray

1 leg xray

2 CT

2 head CT

3 MRI

3 Ortho

data want;

studynum procs imaging

1 xray 1

1 leg xray 1

2 CT 1

2 head CT 1

3 MRI 1

3 Ortho 0

Re: Scan or Find or Count option

Reeza — Tue, 06 Aug 2019 21:50:58 GMT

I think that's just an IF statement or possibly a format.

if upcase(procs) in ("CT", "XRAY", ......) the imaging=1; else imaging=0;

Re: Scan or Find or Count option

Astounding — Tue, 06 Aug 2019 22:00:16 GMT

You have a couple of features that make the problem mildly tricky.

The word you are searching for might not be the first word.

The case might be different (xray vs. XRAY).

Here's one way to approach that:

imaging = findw(procs, 'xray',, 'i') or findw(procs, 'mri',, 'i') or findw(procs, 'ct',, 'i');

It's untested code, so see if it works as planned.

Re: Scan or Find or Count option

novinosrin — Tue, 06 Aug 2019 22:40:37 GMT

data have;
input studynum    procs & $15.;
cards;
1                   xray
1                   leg xray
2                   CT
2                   head CT
3                   MRI
3                   Ortho
;

data want;
set have;
do _n_=1 to countw(procs,' ');
imagining= scan(upcase(procs), _n_,' ') in ("CT", "XRAY", "MRI");
if imagining then leave;
end;
run;

Re: Scan or Find or Count option

hashman — Tue, 06 Aug 2019 23:00:48 GMT

@stancemcgraw :

In a way, you can use the combo of the COUNTW and SCAN functions to get what you want:

data have ;                                                                   
  input @1 studynum @4 procs $20. ;                                           
  cards ;                                                                     
1  xray                                                                       
1  leg xray                                                                   
2  CT                                                                         
2  head CT                                                                    
3  MRI                                                                        
3  Ortho                                                                      
run ;                                                                         
                                                                              
data want ;                                                                   
  set have ;                                                                  
  do _n_ = 1 to countw (procs) until (imaging) ;                              
    if scan (lowcase (procs), _n_) in ("ct", "xray", "mri") then imaging = 1 ;
  end ;                                                                       
  imaging = ^^ imaging ;                                                      
run ;

Kind regards

Paul D.

Re: Scan or Find or Count option

hashman — Wed, 07 Aug 2019 01:17:21 GMT

@novinosrin:

Funny that I hadn't seen your code before posting mine ;).

Re: Scan or Find or Count option

novinosrin — Wed, 07 Aug 2019 01:25:07 GMT

Guru @hashman A disciple merely follows his Guru nontheless. Btw, All over Citizens , they think I'm bizzare to keep busyzaro ball rolling all the time 🙂 Part 3 and 4 are a bit of a learning curve as the concept leaps though fantastic. I a rereading. I shall touch base offline later. Take care and Good night.

PS Pass on my regards to your family and sis if you are still in philly

Re: Scan or Find or Count option

ChrisNZ — Wed, 07 Aug 2019 01:30:21 GMT

Or this :

IMAGING = prxmatch('/CT|XRAY|MRI/i',PROCS) > 0;

Re: Scan or Find or Count option

hashman — Wed, 07 Aug 2019 01:39:42 GMT

@novinosrin :

p.s. Still am. Thanks for the good wishes. Off homeward tomorrow ... a long drive.

Re: Scan or Find or Count option

hashman — Wed, 07 Aug 2019 01:42:13 GMT

@ChrisNZ : That's actually the best approach I can think of, especially since this regex expression is easy to comprehend.

Re: Scan or Find or Count option

ChrisNZ — Wed, 07 Aug 2019 02:10:43 GMT

@hashman Yes, a simple legible expression for once! It's almost troubling... 🙂

Re: Scan or Find or Count option

hashman — Wed, 07 Aug 2019 03:10:57 GMT

@ChrisNZ : Extremely troubling and disturbing, indeed ...