topic Re: Informat for MMM-DD-YY in SAS Programming

Informat for MMM-DD-YY

JW_Hyde — Wed, 31 Jul 2019 12:22:46 GMT

This informat I cannot find. When I use the ANYDTDTE7. informat it comes up with the incorrect SAS date.

Re: Informat for MMM-DD-YY

Kurt_Bremser — Wed, 31 Jul 2019 12:33:03 GMT

Does MMM mean you have a three-letter month name?

In this case, you will have to reshuffle the string before converting:

data have;
input str_date :$9.;
datalines;
jan-01-19
mar-28-18
;

data want;
set have;
num_date = input(substr(str_date,5,2)!!substr(str_date,1,3)!!substr(str_date,8,2),date7.);
format num_date e8601da10.;
run;

Re: Informat for MMM-DD-YY

novinosrin — Wed, 31 Jul 2019 12:43:23 GMT

data want;
given_date='Jan-20-19';
length _t1 $9;
do _i=2,1,3;
_t1=cats(_t1,scan(given_date,_i,'-'));
end;
want_date=input(_t1,date9.);
drop _:;
format want_date date9.;
run;

Re: Informat for MMM-DD-YY

Astounding — Wed, 31 Jul 2019 12:50:10 GMT

Have you tried ANYDTDTE9. ?

When the date contains 9 characters but your informat only reads 7 characters, expect the results to be unusual.

Re: Informat for MMM-DD-YY

JW_Hyde — Wed, 31 Jul 2019 13:19:43 GMT

Thanks very much for the quick response.

Re: Informat for MMM-DD-YY

JW_Hyde — Wed, 31 Jul 2019 13:20:43 GMT

Thanks very much for your quick response. This solution works the best for what I need.

Re: Informat for MMM-DD-YY

ballardw — Wed, 31 Jul 2019 16:39:10 GMT

@Astounding wrote:
Have you tried ANYDTDTE9. ?

When the date contains 9 characters but your informat only reads 7 characters, expect the results to be unusual.

I tried it and fails. But interestingly enough

data want;
given_date='Jan-20-2019';
date = input(given_date,anydtdte11.);
format date date9.;
run;

seems to work just fine. Yet another reason NOT to use 2 digit years.

BTW

data want;
given_date='Jan-20-2019';
date = input(given_date,anydtdte.);
format date date9.;
run;

Fails as well.