topic Re: Check if a variable value by group in SAS Programming

Check if a variable value by group

newboy1218 — Mon, 29 Jul 2019 22:04:47 GMT

Hi.. I have a dataset that organized by customer level and has a variable called 'balance'. I want to check, for each customer, if their balance has ever gone above 500; if it has, how many times.

I thought about using array, but not sure how I can use it in this case. Does anyone have any suggestion?

customer	date	balance
A	201804	200
A	201805	600
A	201806	450
A	201807	1000
B	201712	0
B	201801	50
B	201802	100

customer	date	balance	ever500	over500
A	201804	200	0	0
A	201805	600	1	1
A	201806	450	1	1
A	201807	1000	1	2
B	201712	0	0	0
B	201801	50	0	0
B	201802	100	0	0

Re: Check if a variable value by group

Kurt_Bremser — Mon, 29 Jul 2019 21:47:22 GMT

data want;
set have;
by customer;
retain over500;
if first.customer then over500 = 0;
ever500 = (balance > 500);
over500 + ever500;
run;

Re: Check if a variable value by group

newboy1218 — Mon, 29 Jul 2019 21:51:35 GMT

Thank you. So do I need to sort the dataset by customer and date first?

Re: Check if a variable value by group

newboy1218 — Mon, 29 Jul 2019 22:05:15 GMT

And how can I retain the value of ever500 too?

Re: Check if a variable value by group

Kurt_Bremser — Tue, 30 Jul 2019 05:29:56 GMT

@newboy1218 wrote:
Thank you. So do I need to sort the dataset by customer and date first?

Yes.

Re: Check if a variable value by group

Kurt_Bremser — Tue, 30 Jul 2019 05:36:17 GMT

@newboy1218 wrote:

And how can I retain the value of ever500 too?

Ups, missed that one.

data have;
input customer $ date $ balance;
datalines;
A 201804 200
A 201805 600
A 201806 450
A 201807 1000
B 201712 0
B 201801 50
B 201802 100
;

data want;
set have;
by customer;
retain ever500 over500;
if first.customer
then do;
  ever500 = 0;
  over500 = 0;
end;
if balance > 500 then ever500 = 1;
over500 + (balance > 500);
run;

proc print data=want noobs;
run;

Result now looks exactly like what you want:

customer     date     balance    ever500    over500

   A        201804       200        0          0   
   A        201805       600        1          1   
   A        201806       450        1          1   
   A        201807      1000        1          2   
   B        201712         0        0          0   
   B        201801        50        0          0   
   B        201802       100        0          0

Note how I presented the example data in a data step with datalines, so that the dataset can be created with a simple copy/paste and run. Please do so yourself in the future.

Re: Check if a variable value by group

hashman — Tue, 30 Jul 2019 06:15:15 GMT

@newboy1218:

The way you want your output data set shaped, you need a bit of logic to ensure that:

Before BALANCE becomes >500, EVER500=0
Once BALANCE>500, EVER500=1 propagates though the end of the BY group
OVER500 is incremented only on the records with BALANCE>500

For example (assuming that HAVE is sorted by customer):

data have ;                                 
  input customer :$1. date balance ;        
  cards ;                                   
A  201804   200                             
A  201805   600                             
A  201806   450                             
A  201807  1000                             
B  201712     0                             
B  201801    50                             
B  201802   100                             
run ;                                       
                                            
data want ;                                 
  do until (last.customer) ;                
    set have ;                              
    by customer ;                           
    if not ever500 then ever500 = 0 ;       
    if balance > 500 then ever500 = 1 ;     
    over500 = sum (over500, balance > 500) ;
    output ;                                
  end ;                                     
run ;

It helps that the DATA step auto-resets EVER500 and OVER500 to missing values at the top of the implied loop, i.e. before the DO loop starts iterating.

Kind regards

Paul D.

Re: Check if a variable value by group

newboy1218 — Tue, 30 Jul 2019 13:22:59 GMT

Amazing Thank you!

Re: Check if a variable value by group

newboy1218 — Tue, 30 Jul 2019 13:24:52 GMT

Thank you so much!