topic how to write this condition in macro in SAS Programming

how to write this condition in macro

Aayushi_17 — Tue, 23 Jul 2019 09:00:39 GMT

Hi all,

similarly like this step i have write 24 steps

if shcheck1 = 1 then do;
TERM =Strip(sb1_display);
CAT ='HISTORY' ;
output;
end;

like this

if shcheck2 = 1 then do;
TERM =Strip(sb2_display);
CAT ='HISTORY' ;
output;
end;

if shcheck3 = 1 then do;
TERM =Strip(sb3_display);
CAT ='HISTORY' ;
output;
end;

is there any easy way to give it in a macro for the numbers changing till 24?

Thanks in adv

Re: how to write this condition in macro

gamotte — Tue, 23 Jul 2019 09:09:12 GMT

Hello,

You don't need macro here. Not tested :

data want ;
    set have;

    array shcheck shcheck:;

    do over shcheck;
        if shcheck=1 then do;
            TERM=strip(vvaluex(cats('sb',_i_,'_display')));
            CAT="HISTORY";
            output; 
        end;
    end;
run;

Re: how to write this condition in macro

Patrick — Tue, 23 Jul 2019 09:16:34 GMT

Good that you asked. Try to avoid SAS macro language until you're sufficiently familiar with SAS Base language.

Base SAS Arrays should give you what you need.

data want(drop=_:);
  set have;
  array shchecks {*} shcheck1 - shcheck24;
  array sb_displays {*} sb1_display -- sb24_display;

  do _i=1 to dim(shchecks);
    if shchecks[_i] = 1 then
      do;
        TERM =Strip(sb_displays[_i]);
        CAT ='HISTORY';
        output;
      end;
  end;
run;

Ideally numbered variables have the number at the end as this makes them easy to reference.

In above code "sb<n>_display" got the numbering in the middle so here I couldn't just reference as a list.

Assuming that the variables come one after another in the source dataset I've used the double dash notation. You need to check in your source data if my assumption is correct (use a proc contents on the source table with order=varnum; check in the result if the sb<n> variable really come one after the other with consecutive varnums). If the sb<n> vars are not in consecutive order then you need to write them explicitly in the array definition - like:

array sb_displays {*} sb1_display sb2_display sb3_display ....;

Re: how to write this condition in macro

Aayushi_17 — Tue, 23 Jul 2019 11:13:33 GMT

thank you this one worked