topic Re: 3rd position in SAS Programming

3rd position

BrahmanandaRao — Tue, 02 Jul 2019 15:26:52 GMT

I have a string like
a='a, b, cd, ef, gdj'
How to find 3rd comma

I want 3rd position for above

Data

Re: 3rd position

tsap — Tue, 02 Jul 2019 15:39:23 GMT

DATA WORK.HAVE;
	a='a, b, cd, ef, gdj';
	NEWVar=SCAN(a,3);
RUN;

Result:

a				NEWVar
a, b, cd, ef, gdj		cd

Hope this helps

Re: 3rd position

noling — Tue, 02 Jul 2019 19:27:47 GMT

This works if you want to know which position the 3rd comma is in. Stored in the third_loc var:

data temp(drop= i);
	a='a, b, cd, ef, gdj';
	do i = 1 to length(a);
		if substr(a,i,1)  = "," then comma_cnt+1;
		if comma_cnt=3 then do;
			third_loc=i;
			output;
			stop;
		end;
	end;
run;

Re: 3rd position

tsap — Tue, 02 Jul 2019 19:55:56 GMT

If you were looking for the actual location of the literal third comma punctuation in the text and not the third value (delimited by the commas), you could also use this logic:

data WORK.Have;
	a='a, b, cd, ef, gdj';
 	call scan(a,4,pos,len,',');
  	pos=pos-1;
  	drop len;
run;

resulting output:

Obs 	a 			pos 
1 	a, b, cd, ef, gdj 	9

Showing that the 3rd comma (',') was the 9th character in that text string

ref link to call scan: Sample 41355: Find the nth delimiter in a character string

Re: 3rd position

noling — Tue, 02 Jul 2019 20:27:52 GMT

This is a much better solution than mine. I user an &iterator in scan so much that I forget you can just say "give me the nth value"!

Re: 3rd position

ChrisNZ — Thu, 11 Jul 2019 04:15:35 GMT

Another way:

data _null_;
  A='a, b, cd, ef, gdjh';
  POS=length(prxchange('s/(([^,]*,){3}).*/\1/',1,A));
  put POS=;
run;

POS=9

This expression reads:

Find a group composed of:
(         start of group
([^,]*,)  anything-not-a-comma       repeated as required      then a comma   
                [^,]                          *                      ,

{3}       that combination (not comma then comma) appears thrice
)         end of group

.*        the group is followed by all remaining characters

\1        the second RegEx parameter asks that we only keep the group we matched
          i.e. we keep the three NotComma+Comma groups

Because we discard everything after the third comma, the length function gives us the position we want.

Re: 3rd position

tsap — Wed, 10 Jul 2019 21:04:14 GMT

Were any of the responses provided suitable as a solution to your problem? If so, please mark that post as the solution so that your post will close out as solved. Thanks.

Re: 3rd position

hashman — Wed, 10 Jul 2019 21:49:35 GMT

@BrahmanandaRao :

I actually do like the CALL SCAN and regexen solutions better. But if you wanted to do it in a loop limited to 3 iterations, I can't help but suggest this:

data _null_ ;                    
  retain s 'a, b, cd, ef, gdjh' ;
  _s = s ;                       
  do i = 1 to 3 ;                
    pos = findc (_s, ",") ;      
    substr (_s, pos, 1) = "" ;   
  end ;                          
  put pos= ;                     
run ;

Kind regards

Paul D.

Re: 3rd position

ScottBass — Wed, 10 Jul 2019 23:18:29 GMT

Yet another approach:

DATA WORK.HAVE;
   a='a, b, cd, ef, gdj';
   pos=0;
   do i=1 to 3;
   	pos=findw(a,',',pos+1,',','K');
   end;
   drop i;
RUN;

findw finds "words"

The 1st argument is the string to search.

The 2nd argument defines the "word" to find (a comma).

The 3rd argument defines the starting position for the search. Needed to loop and find the 3rd comma.

The 4th argument defines the delimiters that separate words. In this case the delimiter is also the word we're searching for.

The 5th argument "keeps" the delimiter, i.e. reverses the meaning. A comma is now not treated as a delimiter.

Another approach (similar to hashman's but without the substr):

DATA WORK.HAVE;
   a='a, b, cd, ef, gdj';
   pos=0;
   do i=1 to 3;
   	pos=findc(a,',',pos+1);
   end;
   drop i;
RUN;

P.S.: What are you really trying to do? I doubt you want the position of the 3rd comma; instead, what do you want to do with that position?

Re: 3rd position

hashman — Thu, 11 Jul 2019 00:55:09 GMT

@ScottBass :

Neat! I like your FINDC approach better, but actually both are better than the SUBSTR pseudo-function known to be notoriously slow.

Re: 3rd position

ScottBass — Thu, 11 Jul 2019 03:11:46 GMT

@hashman wrote:

@ScottBass :

Neat! I like your FINDC approach better, but actually both are better than the SUBSTR pseudo-function known to be notoriously slow.

Yeah, I like the FINDC approach better myself.

I started with FINDW, mistakenly thought FINDC didn't have the start position parameter, hit the doc, then decided to post both approaches.

What would be nice is a parameter to "find the Nth occurrence" of [character|word] in FINDC | FINDW. That's where @ChrisNZ 's solution is cool, but I doubt most folks would come up with that (but then Chris isn't "most folks" 😉 ). I suspect the OP will have to hit the Perl Regex docs to understand that (really cool) solution.

Re: 3rd position

ChrisNZ — Thu, 11 Jul 2019 03:42:58 GMT

Ha @ScottBass! Bring on the compliments!

I just don't tire of them somehow! 😉

I feel like I have to add a few lines to explain the RegEx now.

Re: 3rd position

hashman — Thu, 11 Jul 2019 03:46:25 GMT

@ChrisNZ : But indeed.That would't hurt a bit.

Re: 3rd position

ChrisNZ — Thu, 11 Jul 2019 03:54:56 GMT

@hashman Done 🙂

Re: 3rd position

hashman — Thu, 11 Jul 2019 04:02:28 GMT

@ScottBass :

Agree that it would be cool to have a canned function to find the index of the Kth occurrence of a character or word.

Would be neater, as you suggest, to add an extra argument to an existing function, but if my conversations with Rick L. are any indicator, overloading existing SAS functions is much more problematic than creating new ones (I once tried to coax him into adding a parm to the CATs family to specify a format other than the default for auto-converting numeric arguments, and the above was what he said).

On the other note, the problem with the regexen is that those who don't get to use them often (or, better still, day in and day out) have to spend an inordinate time with the docs to comprehend what an expression means and does. So, simpletons like myself in cases like the subject of this thread tend to use something simpler and more readily recognizable, even at the expense of performance (as the regexen are really quite fast).

Kind regards

Paul D.

Re: 3rd position

hashman — Thu, 11 Jul 2019 04:05:35 GMT

@ChrisNZ : Thanks 1e6!

Re: 3rd position

ChrisNZ — Thu, 11 Jul 2019 04:18:38 GMT

@hashman My experience is that Regular Expressions are much more expensive than the "normal" string functions.

And since they are less legible too as you mention, they are not my first choice either.

However, their power means that sometimes they are the only sensible option, as they can replace tens or even hundreds of lines of code where numerous combinations would have to be tested resulting in un-maintainable spaghetti code.

data _null_;   * 0.4 seconds;
  A='a, b, cd, ef, gdjh';
  do I=1 to 1e7;
    call scan(A,4,POS,LEN,',');
    POS=POS-1;
  end;
  put POS=;
run;

data _null_;  * 7.5 seconds;
  A='a, b, cd, ef, gdjh';
  do I=1 to 1e7;
    POS=length(prxchange('s/(([^,]*,){3}).*/\1/o',1,A));
  end;
  put POS=;
run;

Re: 3rd position

hashman — Thu, 11 Jul 2019 04:37:28 GMT

@ChrisNZ :

True. The reason I've mentioned the regexen's purported efficiency is that once on SAS-L someone (unfortunately, don't remember who or the circumstances) showed a regex - which I then tested - that worked much faster than the combos of string functions anyone else (including me) had offered. Could be a fluke ... but got seared in my memory nonetheless.