topic Re: combining tables vertically - resut output in SAS Programming

combining tables vertically - resut output

Ccasagran737 — Tue, 09 Jul 2019 15:58:12 GMT

Hy,

I'm running this program:

proc sql;
	select  "TOTAL" as dest,
			sum(Boarded) as Boarded format comma.
 	from sasuser.LAGUARDIA
 		outer union  
		 	select Dest,
		 		   sum(Boarded) as Boarded format comma.
		 	from sasuser.LAGUARDIA
		 	group by Dest;
quit;

and SAS shows me this result:

I'd like to see the result of the first query (total boarded) just under the result of the second query (total boarded group by destination) without missing data. Something like this:

Is it possible? If yes, could you help me...thank a lot!

Have a nice day,

Daniele

Re: combining tables vertically - resut output

novinosrin — Tue, 09 Jul 2019 16:12:18 GMT

hi @Ccasagran737

Try using UNION instead of OUTER UNION

Re: combining tables vertically - resut output

novinosrin — Tue, 09 Jul 2019 16:14:57 GMT

Well, with the above being said, if you still want to force OUTER UNION to overlay columns corresponding to the first select query, then

try OUTER UNION Corr

But please restrain such practices in a production code.

Re: combining tables vertically - resut output

Reeza — Tue, 09 Jul 2019 16:17:46 GMT

Do you have to use PROC SQL? Tabulate wold be more appropriate here.

Re: combining tables vertically - resut output

Reeza — Tue, 09 Jul 2019 16:36:59 GMT

proc tabulate data=sashelp.baseball;
class Team ;
var salary;
table (all = 'Total' team =''), Salary*Sum*f=dollar20. ;
run;

Re: combining tables vertically - resut output

Tom — Tue, 09 Jul 2019 16:53:32 GMT

Drop the OUTER and let UNION work as intended.

If you want to impose an order than spell it out.

proc sql;
  select  "TOTAL" as sex 
       , sum(weight) as weight format comma.
       ,  1 as ordervar
  from sashelp.class
union
  select sex
       , sum(weight) as weight format comma.
       , 2 as ordervar
  from sashelp.class
  group by sex
  order by ordervar, sex
  ;
quit;