topic splitting an appended variable in SAS Programming

splitting an appended variable

dennis_oz — Tue, 25 Jun 2019 06:51:38 GMT

hi all , please can you help me with this requirement
thanks in advance.
input dataset

Id claim_list
----- -----------------
abc 123, 456 ,789
def
ghi 111,222,333

my output requirement:

id claim_id
abc 123
abc 456
abc 789
def
ghi 111
ghi 222
ghi 333

Re: splitting an appended variable

Kurt_Bremser — Tue, 25 Jun 2019 08:32:59 GMT

Use countw(), scan(), and a conditional do loop:

data have;
infile datalines truncover;
input Id $ claim_list :$20.;
datalines;
abc 123,456,789
def
ghi 111,222,333
;

data want;
set have;
length claim_id $3;
if countw(claim_list,',') > 0
then do i = 1 to countw(claim_list,',');
  claim_id = scan(claim_list,i,',');
  output;
end;
else output;
keep id claim_id;
run;

proc print data=want noobs;
run;

Result:

Id     claim_id

abc      123   
abc      456   
abc      789   
def            
ghi      111   
ghi      222   
ghi      333

Re: splitting an appended variable

dennis_oz — Tue, 25 Jun 2019 21:10:43 GMT

thanks for this . deeply appreciated