topic Re: Check Macro character variable value inside a %if condition in SAS Programming

Check Macro character variable value inside a %if condition

dwights — Wed, 19 Jun 2019 18:52:40 GMT

I'm trying to check the value of the character macro variable 'char_varzxy ' in a %if condition. The if loop is not being executed even if the condition holds true. Can someone please let me know why

%do i=1 %to &N;

/*   Code to get the table  containing 'FLG' variable on which chi-square test is being run.
*
*
*
*
*/

   

ods exclude all;
proc freq data=temp2 ORDER=formatted; 
tables &variable / TestP=(&P_Values); 
ods output OneWayFreqs=FreqOut OneWayChiSq=ChiSData;
output out=FreqStats N ChiSq;
run;
ods exclude none;

data ChiSqData2;
set ChiSData;
num_varu = input(cValue1,32.30);
char_varz= put(cValue1,12.8);

run;


proc sql noprint;
select nValue1 into :nValue1 from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select num_varu into :num_vary from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select cValue1 into :prob_vary from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select char_varz into :char_varzxy from ChiSqData2 where Label1='Pr > ChiSq';
quit;



%if(&char_varzxy ='<.0001') %then %do;

/*     Not entering this loop       */                     

%end;

%end;

The chisqdata2 table which contains the character variable is as follows -

Table	Name1	Label1	cValue1	nValue1	num_varu	char_varz
Variable FLG	_PCHI_	Chi-Square	1246.522	1246.52212	1246.5221	1246.522
Variable FLG	DF_PCHI	DF	1	1	1.00E-30	1
Variable FLG	P_PCHI	Pr > ChiSq	<.0001	4.73E-273	.	<.0001

Re: Check Macro character variable value inside a %if condition

Kurt_Bremser — Wed, 19 Jun 2019 19:05:59 GMT

Since the macro processor works with text only, quotes around strings are not needed.

%if &char_varzxy = <.0001 %then %do;

%if "&char_varzxy" = "<.0001" %then %do;

Re: Check Macro character variable value inside a %if condition

Reeza — Wed, 19 Jun 2019 19:06:57 GMT

If you do the following, what shows up?

%PUT &char_varzxy;

The variable may be numeric and the <0.001 is a formatted display so the value saved may be the exact value rather than the formatted value.

@dwights wrote:

I'm trying to check the value of the character macro variable 'char_varzxy ' in a %if condition. The if loop is not being executed even if the condition holds true. Can someone please let me know why
%do i=1 %to &N;

/*   Code to get the table  containing 'FLG' variable on which chi-square test is being run.
*
*
*
*
*/

   

ods exclude all;
proc freq data=temp2 ORDER=formatted; 
tables &variable / TestP=(&P_Values); 
ods output OneWayFreqs=FreqOut OneWayChiSq=ChiSData;
output out=FreqStats N ChiSq;
run;
ods exclude none;

data ChiSqData2;
set ChiSData;
num_varu = input(cValue1,32.30);
char_varz= put(cValue1,12.8);

run;


proc sql noprint;
select nValue1 into :nValue1 from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select num_varu into :num_vary from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select cValue1 into :prob_vary from ChiSqData2 where Label1='Pr > ChiSq';
quit;

proc sql noprint;
select char_varz into :char_varzxy from ChiSqData2 where Label1='Pr > ChiSq';
quit;



%if(&char_varzxy ='<.0001') %then %do;

/*     Not entering this loop       */                     

%end;

%end;
The chisqdata2 table which contains the character variable is as follows -

Table Name1 Label1 cValue1 nValue1 num_varu char_varz

Variable FLG _PCHI_ Chi-Square 1246.522 1246.52212 1246.5221 1246.522

Variable FLG DF_PCHI DF 1 1 1.00E-30 1

Variable FLG P_PCHI Pr > ChiSq <.0001 4.73E-273 . <.0001

Re: Check Macro character variable value inside a %if condition

dwights — Wed, 19 Jun 2019 19:10:26 GMT

It prints the following -

char_varzxy = <.0001

Re: Check Macro character variable value inside a %if condition

Kurt_Bremser — Wed, 19 Jun 2019 19:14:22 GMT

@dwights wrote:

It prints the following -

char_varzxy = <.0001

See? No quotes.

Re: Check Macro character variable value inside a %if condition

dwights — Wed, 19 Jun 2019 21:30:54 GMT

Thanks for replying. I tried both of them. None worked.

Re: Check Macro character variable value inside a %if condition

Tom — Thu, 20 Jun 2019 00:51:06 GMT

I don't see any code where you are putting single quotes into the value of the macro variable. Unless that is what the ODS output does, but I doubt that.

You do appear to be putting trailing spaces into the value of the macro variable however.

select char_varz into :char_varzxy from ChiSqData2 where Label1='Pr > ChiSq';

Either remove the trailing spaces.

%let char_varzxy=&char_varzxy;

Or don't put them into the value to begin with by adding the TRIMMED keyword to the INTO clause.

select char_varz
  into :char_varzxy trimmed
from ChiSqData2 
where Label1='Pr > ChiSq'
;

Because your macro variable contains < you should use quoting to avoid confusing SAS about what test you are doing. It is probably easier to use actual quotes instead of macro quoting.

%if "<.0001" = "&char_varzxy" %then ....

Make sure to use double quote character and not single quote character because macro variable references are not resolved inside of single quotes. Make sure both sides use the same quote character. A single quote character is not equal to a double quote character.

Re: Check Macro character variable value inside a %if condition

Tom — Thu, 20 Jun 2019 00:49:16 GMT

@Reeza That test will not reveal leading/trailing spaces.

Use something like this instead:

%PUT |&char_varzxy|;

Re: Check Macro character variable value inside a %if condition

dwights — Thu, 20 Jun 2019 15:01:22 GMT

Thank you very much! The trimmed keyword and the double quotes helped me.