topic Re: How Can I Merge Cells in RTF Output (SAS 9.3)? in SAS Programming

How Can I Merge Cells in RTF Output (SAS 9.3)?

KentaMURANAKA — Thu, 13 Jun 2019 11:48:00 GMT

Hi, All:

I am trying to generate output like this in RTF Output, which has one merged cell (Column No.2 + Column No. 3)

I think nested structure in column statement is one of solutions, but I do not know how to write code.

I attached example code. Please help me.

Thank you in advance.

data test;
    length column1-column3 $200.;
    column1="aaaaa"; column2="bbbbb"; column3="ccccc"; output;
run;
ods rtf file="SpecifyYourFolder\test.rtf";
proc report data=test nowindows
    style(header)={backgroundcolor=white fontweight=light fontsize=8pt fontfamily="Times New Roman"}
    style(report)={rules=groups frame=hsides borderwidth=0.5pt bordercolor=black}
    ;
    column
        column1
        (
        "BBB+CCC" column2 column3
        )
    ;
    define column1 / display "AAAAA";
    define column2 / display "";
    define column3 / display "";
run;
quit;
ods rtf close;

Re: How Can I Merge Cells in RTF Output (SAS 9.3)?

ballardw — Thu, 13 Jun 2019 14:39:36 GMT

Consider

proc report data=test nowindows
    style(header)={backgroundcolor=white fontweight=light fontsize=8pt fontfamily="Times New Roman"}
    style(report)={rules=groups frame=hsides borderwidth=0.5pt bordercolor=black}
    ;
    column
        ("AAAAA" column1)
        
        ("BBB+CCC" column2 column3 )
            ;
    define column1 / display "" ;
    define column2 / display "";
    define column3 / display "";
run;
quit;

Mixing the way you define the column headings between DEFINE and COLUMN statements is adding the additional row,

Re: How Can I Merge Cells in RTF Output (SAS 9.3)?

KentaMURANAKA — Fri, 14 Jun 2019 00:34:12 GMT

Hi, ballardw-san:

Thank you for your quick reply. Your code worked for me.

Yes, I had trouble with additional row that I do not intend.

Thanks to your explanation, I understand.

Thank you for giving details!!