topic Re: How to replace special symbol by space in SAS Programming

How to replace special symbol by space

thanikondharish — Tue, 11 Jun 2019 07:25:42 GMT

Data have;
String1='aaaaa*bbbb*ddddddd@jjjjjj';
Output;
String2='&aaaa*ggggghgg####';
Output;
Run;

How to replace special symbols by space

Re: How to replace special symbol by space

PeterClemmensen — Tue, 11 Jun 2019 07:48:28 GMT

When you say 'Special Symbols', do you simply mean *, @, &, # or?

Re: How to replace special symbol by space

thanikondharish — Tue, 11 Jun 2019 07:51:16 GMT

If more symbols how can do

Re: How to replace special symbol by space

PeterClemmensen — Tue, 11 Jun 2019 08:02:25 GMT

One way is to use PRXCHANGE like this. You can add more symbols of you like.

Data have;
String1='aaaaa*bbbb*ddddddd@jjjjjj';
String2='&aaaa*ggggghgg####';
Run;

data want;
 set have;
 String1 = prxchange('s/[*@&#]/ /', -1, String1);
 String2 = prxchange('s/[*@&#]/ /', -1, String2);
run;

Re: How to replace special symbol by space

gamotte — Tue, 11 Jun 2019 08:08:34 GMT

Converseley, you can indicate which characters you do not want to be replaced by spaces.

For instance, the following program wil replace all characters but alphanumerics and '_' with spaces :

data want;
 set have;
 String1 = prxchange('s/[^\w]/ /', -1, String1);
 String2 = prxchange('s/[^\w]/ /', -1, String2);
run;

Re: How to replace special symbol by space

thanikondharish — Tue, 11 Jun 2019 08:17:15 GMT

Don't mention symbols in coding

Re: How to replace special symbol by space

Tom — Tue, 11 Jun 2019 13:27:35 GMT

You can use the TRANSLATE() function to replace characters.

Example:

data have;
  input string $40. ;
cards;
aaaaa*bbbb*ddddddd@jjjjjj
&aaaa*ggggghgg####
;

data want ;
  set have;
  new_string=translate(string,' ','*&#@');
run;

Results:

Obs             string              new_string

 1     aaaaa*bbbb*ddddddd@jjjjjj    aaaaa bbbb ddddddd jjjjjj
 2     &aaaa*ggggghgg####            aaaa ggggghgg

If you are not sure what to replace perhaps you use the COMPRESS() function to get the list of non-alpha characters in the string.

data want ;
  set have;
  new_string=translate(string,' ',compress(string,,'ad'));
run;

Re: How to replace special symbol by space

thanikondharish — Tue, 11 Jun 2019 13:43:16 GMT

Sorry already I have done with same code .
Is there any other way

Re: How to replace special symbol by space

ballardw — Tue, 11 Jun 2019 15:26:36 GMT

@thanikondharish wrote:
Data have;
String1='aaaaa*bbbb*ddddddd@jjjjjj';
Output;
String2='&aaaa*ggggghgg####';
Output;
Run;

How to replace special symbols by space

SHOW the required output or explicitly list which characters you consider "special characters". For some purpose I might consider "a" as a "special character".