topic Re: replace strings among (), [], {}, ' ', " " as the same number of X in SAS Programming

replace strings among (), [], {}, ' ', " " as the same number of X

Alexxxxxxx — Thu, 06 Jun 2019 22:03:24 GMT

Dear all,

How can I replace strings among (), [], {}, ' ', " " as the same number of Xs

for the following words,

data HAVE;
input NAME :& $800.;
cards;
ALLCELLS BIOLOGICAL TECHNOLOGY (SHAN) COMPANY
ALLEGRO ASIA TECHNOLOGY (D.B.A.)
ALLEN BROTHERS 'FITTINGS'
ALLEN R. NELSON ENGINEERING (1997)
ALLENS MESHCO (PROPRIETARY & MANUFACTURING)
ALLERGY THERAPEUTICS {UK}
ALLES GOED [PTY] LIMITED, TRADING AS PIPE & PLANT INSULATION
run;

I expect to get

NAME	Expect
ALLCELLS BIOLOGICAL TECHNOLOGY (SHAN) COMPANY	ALLCELLS BIOLOGICAL TECHNOLOGY (XXXX) COMPANY
ALLEGRO ASIA TECHNOLOGY (D.B.A.)	ALLEGRO ASIA TECHNOLOGY (X.X.X.)
ALLEN BROTHERS 'FITTINGS'	ALLEN BROTHERS 'XXXXXXXX'
ALLEN R. NELSON ENGINEERING (1997)	ALLEN R. NELSON ENGINEERING (XXXX)
ALLENS MESHCO (PROPRIETARY & MANUFACTURING)	ALLENS MESHCO (XXXXXXXXXXX & XXXXXXXXXXXXX)
ALLERGY THERAPEUTICS {UK}	ALLERGY THERAPEUTICS {XX}
ALLES GOED [PTY] LIMITED, TRADING AS PIPE & PLANT INSULATION	ALLES GOED [XXX] LIMITED, TRADING AS PIPE & PLANT INSULATION

Could you please give me some suggestions about this?

thanks in advance.

Re: replace strings among (), [], {}, ' ', " " as the same number of X

SASKiwi — Fri, 07 Jun 2019 02:49:37 GMT

This is pretty ugly but it appears to work. It is using the ability of the SUBSTR function to edit part of a character variable.

data HAVE;
input NAME :& $800.;
length char1 char2 $1;
do chars = '()', "''", '{}', '[]';
  char1 = substr(chars,1,1);
  char2 = substr(chars,2,1);
  if findc(NAME,char1) and findc(NAME,char2) then 
    substr(name, findc(NAME,char1) + 1, findc(NAME,char2, findc(NAME,char1)+1) - findc(NAME,char1)-1)
    = repeat('X', findc(NAME,char2, findc(NAME,char1)+1) - findc(NAME,char1)-1) ; 
end;
put name = ;
cards;
ALLCELLS BIOLOGICAL TECHNOLOGY (SHAN) COMPANY
ALLEGRO ASIA TECHNOLOGY (D.B.A.)
ALLEN BROTHERS 'FITTINGS'
ALLEN R. NELSON ENGINEERING (1997)
ALLENS MESHCO (PROPRIETARY & MANUFACTURING)
ALLERGY THERAPEUTICS {UK}
ALLES GOED [PTY] LIMITED, TRADING AS PIPE & PLANT INSULATION
;
run;

Re: replace strings among (), [], {}, ' ', " " as the same number of X

Ksharp — Sat, 08 Jun 2019 16:26:42 GMT

If there is only one pattern in an obs, that would be easy.

data HAVE;
input NAME :& $800.;
call scan(name,2,p,l,'()[]{}''"','m');
temp=prxchange('s/\w/X/i',-1,substr(name,p,l));
substr(name,p,l)=temp;
cards;
ALLCELLS BIOLOGICAL TECHNOLOGY (SHAN) COMPANY
ALLEGRO ASIA TECHNOLOGY (D.B.A.)
ALLEN BROTHERS 'FITTINGS'
ALLEN R. NELSON ENGINEERING (1997)
ALLENS MESHCO (PROPRIETARY & MANUFACTURING)
ALLERGY THERAPEUTICS {UK}
ALLES GOED [PTY] LIMITED, TRADING AS PIPE & PLANT INSULATION
;
run;

proc print;run;

Re: replace strings among (), [], {}, ' ', " " as the same number of X

Alexxxxxxx — Sun, 09 Jun 2019 13:26:08 GMT

Many thanks

Re: replace strings among (), [], {}, ' ', " " as the same number of X

Alexxxxxxx — Sun, 09 Jun 2019 13:26:58 GMT

Thanks for your suggestion

Re: replace strings among (), [], {}, ' ', " " as the same number of X

ChrisNZ — Sun, 09 Jun 2019 23:35:46 GMT

Other options:

data WANT1;
  set HAVE;
  TMP=NAME;
  do while(1);
    NEW=prxchange('s/ (\[.*?) [^X] (.*?\]) /$1X$2/x', -1, TMP);
    NEW=prxchange('s/ ( {.*?) [^X] (.*?} ) /$1X$2/x', -1, NEW);
    NEW=prxchange('s/ (\(.*?) [^X] (.*?\)) /$1X$2/x', -1, NEW);
    NEW=prxchange('s/ (''.*?) [^X] (.*?'') /$1X$2/x', -1, NEW);
    if TMP=NEW then leave ;
    else TMP=NEW;
  end;
  keep NAME NEW;
run;
         
data WANT2; 
  set HAVE;                              
  do PAIRS = '()', "''", '{}', '[]';
    POS1=findc(NAME,char(PAIRS,1));
    POS2=findc(NAME,char(PAIRS,2),POS1+1);     
    if 0 < POS1 < POS2-1 then 
      substr(NAME, POS1 + 1, POS2 - POS1 -1) = repeat('X', POS2 - POS1 - 2) ; 
  end;
run;

Re: replace strings among (), [], {}, ' ', " " as the same number of X

ChrisNZ — Mon, 10 Jun 2019 10:22:22 GMT

@Ksharp Do you know why the DO UNTIL loop is needed in my example, and the -1 recursion in prxchange is not enough?

Re: replace strings among (), [], {}, ' ', " " as the same number of X

Ksharp — Mon, 10 Jun 2019 14:08:31 GMT

Sorry. No idea.

Re: replace strings among (), [], {}, ' ', " " as the same number of X

Ksharp — Mon, 10 Jun 2019 14:26:55 GMT

Sorry. No idea.