topic Re: Changing from numerical data to date using SAS ondemand in SAS Programming

Changing from numerical data to date using SAS ondemand

nevennett — Fri, 07 Jun 2019 09:02:54 GMT

Hi,

I'm using SAS on demand and I'm struggling to change a numeric variable to a SAS date.

My numeric variable is SurgStart which has format best12. and informat best32. It contains 8 digits that represents YYYYMMDD

What I want to do is changed SurgStart e.g.20140410 to become the date 2014 04 10 so I can then do time series analysis.

My code is:

data ab1;

set ab;

SurgDate=input(put(SurgStart, best12.), yyyymmdd.);
format SurgDate date8.;
run;

This doesn't work.

Please help!

PeterClemmensen — Fri, 07 Jun 2019 09:25:48 GMT

You're close 🙂 Use the Best8. Format and the appropriate yymmdd8. Informat

data _null_;
    SurgStart=20140410;
    SurgDate=input(put(SurgStart, best8.), yymmdd8.);
    put SurgStart= SurgDate= date8.;
run;

ErikLund_Jensen — Fri, 07 Jun 2019 09:25:40 GMT

Try this instead:

SurgDate=input(put(SurgStart, 8.), yymmdd8.);

anushreebiotech — Fri, 07 Jun 2019 09:30:07 GMT

Hi,

data have;
input Surgstart;
datalines;
20140410
;
run;

data want;
set have;
SurgDate=Input( Put( Surgstart, 8.), Yymmdd10.);
format SurgDate Yymmdd10.;
run;

ChrisNZ — Fri, 07 Jun 2019 11:20:42 GMT

or even

SurgDate=input(cats(SurgStart), yymmdd8.);

nevennett — Wed, 12 Jun 2019 08:54:26 GMT

Thanks everyone for answering my question. A combination of the responses seems to have done the trick:

data ab1;
set ab;
SurgDate=input(put(SurgStart, 8.),yymmdd8.);
format SurgDate yymmdd8.;
run;

Thank you so much!