topic Re: How to extract this string? in SAS Programming

How to extract this string?

Ganeshk — Tue, 04 Jun 2019 03:45:34 GMT

Hi team,

I have a dataset with a variable path, I need to extract the path till last but one and save it as new variable. Example:
Path;
/c:/user/new/path1/path2/path3/path4/cjx.sas
/c:/user/old/new/path1/path2/path3/path4/cjx.sas
/c:/user/new/path5/path2/path3/path4/cjx.sas
/c:/user/old/new/path5/path2/path3/path4/cjx.sas

What I want is:
Path_1;
/c:/user/new/path1/path2/path3/path4/
/c:/user/old/new/path1/path2/path3/path4/
/c:/user/new/path5/path2/path3/path4/
/c:/user/old/new/path5/path2/path3/path4/

Regards,
GK

Re: How to extract this string?

heffo — Tue, 04 Jun 2019 03:55:19 GMT

Would this work:

data want;
	FilePath = "/c:/user/new/path1/path2/path3/path4/cjx.sas";
	Folder = substr(FilePath,1,length(FilePath)-length(scan(FilePath,-1,"/")));
run;

Re: How to extract this string?

andreas_lds — Tue, 04 Jun 2019 05:48:05 GMT

Or by using substr and findc:

data have_want;
   length path directory $ 200;

   input path;

   directory = substr(path, 1, findc(path, '/', 'b'));

datalines;
/c:/user/new/path1/path2/path3/path4/cjx.sas
/c:/user/old/new/path1/path2/path3/path4/cjx.sas
/c:/user/new/path5/path2/path3/path4/cjx.sas
/c:/user/old/new/path5/path2/path3/path4/cjx.sas
;
run;

Re: How to extract this string?

anushreebiotech — Tue, 04 Jun 2019 05:52:12 GMT

Hi,

data have;
input path $50.;
datalines;
/c:/user/new/path1/path2/path3/path4/cjx.sas
/c:/user/old/new/path1/path2/path3/path4/cjx.sas
/c:/user/new/path5/path2/path3/path4/cjx.sas
/c:/user/old/new/path5/path2/path3/path4/cjx.sas
;
run;

data want;
set have;
new_path= Tranwrd(path,'cjx.sas',"");
run;

Regards,

Anushree

Re: How to extract this string?

Ksharp — Tue, 04 Jun 2019 12:53:58 GMT

data have_want;
   length path directory $ 200;

   input path;

   directory = prxchange('s/[^\/]+$//',1,strip(path));

datalines;
/c:/user/new/path1/path2/path3/path4/cjx.sas
/c:/user/old/new/path1/path2/path3/path4/cjx.sas
/c:/user/new/path5/path2/path3/path4/cjx.sas
/c:/user/old/new/path5/path2/path3/path4/cjx.sas
;
run;

proc print;run;