topic Re: In a Stored Process, using _webout and <select> statement how do I call variable in SAS Programming

In a Stored Process, using _webout and statement how do I call variable

gamotte — Mon, 03 Jun 2019 14:21:47 GMT

Hello,

Please post a minimal code that replicates your problem in order to avoid distracting

the reader with unnecessary details.

I did not read all your code but i see that your select tag lacks a name in order for its value to be sent to the server.

For instance if you use the tag

the selected value will be sent to the server wich can retrieve it through the macro variable &schoolNo.

Re: In a Stored Process, using _webout and statement how do I call variable

gamotte — Mon, 03 Jun 2019 15:11:11 GMT

Hello,

here is a simple code that sends the value from a select to the server and displays it :

data have;
input values;
cards;
1
2
3
4
5 
;
run;

%macro main;
    %global sasval;

    data _NULL_;
        file _webout;
        put "<html><body><form method='post' action='&path_to_stp.'>";


        %if &sasval.ne %then %do;
            put "<p>Current value &sasval.</p>";
        %end;

        put "<select name='sasval'>";
        do until (eof);
            set have end=eof;
            put "<option value='" values+(-1) "'>" values+(-1) "</option>";
        end;
        put "</select>";
        put "<button type='submit'>OK</button>";
        put '</form></body></html>';

        stop;
    run;

%mend;

%main;

The same stored process is used for displaying the select and the selected value after validation.

Re: In a Stored Process, using _webout and statement how do I call variable

gamotte — Tue, 04 Jun 2019 08:47:55 GMT

Something like this ?

data schools;
    input id school $;
    cards;
1 School1
2 School2
3 School3
4 School4
5 School5
;
run;

data students;
    input idSch idStud student $;
    cards;
1 1 Smith
1 2 Jones
2 1 Brown
2 2 Davis
3 1 King
3 2 Young
4 1 Hill
4 2 Lee
5 1 White
5 2 Baker
;
run;

%macro display_form;

    data _NULL_;
        file _webout;

        put "<html><body><form method='post''>";

        put "<select id='schoolNo' name='schoolNo' onchange='retrieveStuds()'>";
        put "<option disabled selected>-- Choose a school --</option>";
        do until (eof);
            set schools end=eof;
            put "<option value='" id+(-1) "'>" school+(-1) "</option>";
        end;
        put "</select><br>";
        put "<select id='studNo'>"
        put "<option disabled selected>-- Choose a student --</option>";
        put "</select><br>";

        put "<script src='https://code.jquery.com/jquery-1.11.3.js'></script>";
        put "<script type='text/javascript'>";
        put "function retrieveStuds() {";
        put "    $.ajax({";
        put "        url: window.location.href,";
        put "        type: 'POST',";
        put "        data: '%nrstr(&schoolNo)='+$('#schoolNo').val(),";
        put "        dataType:'json',";
        put "        success: function (data) {";
        put "            $('#studNo option:gt(0)').remove()";
        put "            var arrayStud=data['SASTableData+STUDENTS'];";
        put "            $.each(arrayStud, function() {";
        put "                $('#studNo').append($('<option>').val($(this)[0]['idStud']).html($(this)[0]['student']))";
        put "            })";
        put "        }";
        put "    });";
        put "}";
        put "</script>";

        put '</form></body></html>';

        stop;
    run;

%mend;

%macro main;

    %global schoolNo;

    %if &schoolNo.= %then %do;
        %display_form;
    %end;
    %else %do;

        data _NULL_;    
            rc=appsrv_header('Content-type:','application/json');
        run;

        proc json out=_webout;
            export students (where=(idSch=&schoolNo.));
        run;
    %end;

%mend;

%main;

Re: In a Stored Process, using _webout and

topic Re: In a Stored Process, using _webout and <select> statement how do I call variable in SAS Programming

Re: In a Stored Process, using _webout and statement how do I call variable cuevasj — Mon, 03 Jun 2019 16:21:58 GMT Thank you for your response. I am not sure that we are talking about the same thing. . . Re: In a Stored Process, using _webout and statement how do I call variable

Re: In a Stored Process, using _webout and statement how do I call variable cuevasj — Tue, 04 Jun 2019 11:38:19 GMT Exactly like this. Thank You!

Re: In a Stored Process, using _webout and statement how do I call variable

Re: In a Stored Process, using _webout and