topic How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement? in SAS Programming

How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement?

KentaMURANAKA — Mon, 03 Jun 2019 10:05:53 GMT

Hi, All:

I would like to display footnote, ***NA means "Not Applicable"***, by using PROC REPORT's Line statement, like my following code.

But this code does not generate what I want, only one period (".").

%let _foot1=NA means "Not Applicable".;
data test;
    do item=1 to 5 by 1;
        pagenum=1; output;
    end;
run;
ods rtf file="PleaseSpecifyYourOwnFolder\test.rtf";
proc report data=test style(report)={rules=groups frame=above};
    column item pagenum;
    define pagenum / order noprint;
    define item / display;
    break after pagenum / page;
    compute after _page_;
        line "&_foot1.";
    endcomp;
run;
quit;
ods rtf close;

I tried to use quoting like this, ***%let _foot1=%str(NA means %"Not Applicable%".);***, but same result.

I think there may be problems about Double Quotations, because if deleting Double Quotations, i.e., using ***%let _foot1=NA means Not Applicable***, I can display what I want.

I have no idea, please help me.

Thank you in advance.

Re: How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement

Astounding — Mon, 03 Jun 2019 10:28:46 GMT

As long as your post shows the actual problem and not a simplified version, I would use:

%let _foot1 = 'NA means "Not Applicable".';

Then later:

line &_foot1.;

Re: How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement

KentaMURANAKA — Mon, 03 Jun 2019 10:41:16 GMT

Hi, Astounding-san:

Your code worked. Wonderful.

Thank you for your kind cooperation.

Re: How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement

ballardw — Mon, 03 Jun 2019 17:51:20 GMT

%let _foot1=NA means ""Not Applicable"".;

Two quotes resolve as one in general.

So your resolution of

 line "&_foot1.";

becomes

 line "NA means ""Not Applicable"".";

proc report data=test style(report)={rules=groups frame=above};
    column item pagenum;
    define pagenum / order noprint;
    define item / display;
    break after pagenum / page;
    compute after _page_;
        line "NA means ""Not Applicable"".";
    endcomp;
run;

runs just fine. This use two quotes in literal text works almost anywhere in SAS code.

Such as

data work.junk;
    x="This is a string with "" embedded in a variable.";
run;

Re: How Can I Display Footnote that includes Double Quotations by Using PROC REPORT's Line Statement

KentaMURANAKA — Tue, 04 Jun 2019 01:30:49 GMT

Hi, ballardw-san:

Your answer also works greatly.

Thank you for quick response.