topic Re: how can i get the value 01 instead of 1 after evaluate it in macro variable? in SAS Programming

how can i get the value 01 instead of 1 after evaluate it in macro variable?

Kayla_Tan222 — Mon, 03 Jun 2019 07:29:45 GMT

Hi, i have use %macro variable so that i only need to enter the date i want everytime, However i was facing some issue in my code.

Fo Ex: for the MTH (month) that i pointed with an arrow in the code below, if i want year to be 2019 and the month is 02, the result get i want to be 01 (which is January) instead of only 1.

This is because, there is some pathway for me to read the data will have 201901 and not 20191

%macro date(YYYY=2019, MM=02,Y=2019,M=02);%global YR MTH ACCYRFY;

(body........)

%if &MM = 01 %then %do;

%let YR = %eval(&YYYY - 1);

%let MTH = 12;

%let ACCYRFY = &YYYY;

%end;

%else %if &MM=12 %then %do;

%let YR = &YYYY;

%let MTH = %eval(&MM-1);

%let ACCYRFY = %eval(&YYYY+1);

%end;

%else %do;

%let YR = &YYYY;

%let MTH = %eval(&MM-01); <-The result i get will be 1 instead of 01 if use this code.

%let ACCYRFY = &YYYY;

%end;

libname pl&YR&MTH. "C:\Data\POLA\&YR\&YR&MTH\DBF";

data pl&YR&MTH..pola_motor_clm_agg_&YR&MTH.;

set pl&YR&MTH..pola_motor_clm_agg_&YR&MTH.;

run;

libname pl&Y&M. "C:\Data\POLA\&Y\&Y&M\DBF";

data pl&Y&M..pola_motor_clm_agg_&Y&M.;

set

pl&YR&MTH..pola_motor_clm_agg_&YR&MTH.

pl&Y&M..pola_motor_clm_mth_&Y&M.;

%mend date;

%date(YYYY=2019,MM=02,Y=2019,M=02);

run;

how can i solve this problem?

Re: how can i get the value 01 instead of 1 after evaluate it in macro variable?

Shmuel — Mon, 03 Jun 2019 07:51:21 GMT

You are trying to compute the previous month. That will be much easier to be done by a data step:

%macro date(YYYY=2019, MM=02,Y=2019,M=02);
  %global YR MTH ACCYRFY;
  
  data _NULL_;
       date1 = mdy(&mm, 01, &yyyy);
	   date2 = intnx('month', date1, -1);
	   call symput('datex',put(date2,yymmn6.));
	   /* datex replaces &yy&mth or you can define: */
	   call symput('yy', put(year(date2),4.));
	   call symput('mth',put(month(date2),z2.));
  run;
  
  ......
%mend date;

Re: how can i get the value 01 instead of 1 after evaluate it in macro variable?

Kayla_Tan222 — Mon, 03 Jun 2019 08:18:51 GMT

Sorry Shmuel, can you explain it more detail? coz actually I'm using the macro variable with some condition (I'm using if statement). it seems like unable to use your method is it is with the condition? I'm not so sure

%if &MM = 01 %then %do;

%let YR = %eval(&YYYY - 1);

%let MTH = 12;

%let ACCYRFY = &YYYY;

%end;

%else %if &MM=12 %then %do;

%let YR = &YYYY;

%let MTH = %eval(&MM-1);

%let ACCYRFY = %eval(&YYYY+1);

%end;

%else %do;

%let YR = &YYYY;

%let MTH = %eval(&MM-01); <-The result i get will be 1 instead of 01 if use this code.

%let ACCYRFY = &YYYY;

%end;

Re: how can i get the value 01 instead of 1 after evaluate it in macro variable?

Shmuel — Mon, 03 Jun 2019 08:38:44 GMT

You are using conditions to check:

- if current month is January then to compute previous moth you subtract 1 from year and assign month to 12

- otherwise you subtract 1 from the month.

The function MDY computes a sas date, which is numeric - counting the days from Jan 01, 1960 as zero.

The function INTNX computes a new date from a given date and time interval - in your case -1 month. There is

a third argument to define same day as in given date, last day or first day of the month. The default value is beginning of month,

that is 01. Anyway you don't use the day in your code.

The function CALL SYMPUT assigns a value to a macro variable. Firs argument is the name of the macro variable

and the 2nd argument is its value.

The function put is used to convert the numeric date into yyyymm format (yymmn6. format).

I suggest you should read the documentation of those functions by searching google:

" sas documentation <function xxxxxx>"

Re: how can i get the value 01 instead of 1 after evaluate it in macro variable?

Astounding — Mon, 03 Jun 2019 09:58:54 GMT

Simplest: combine the year and month ahead of time.

%let ym = %eval(100 * &yr + &mth);

If you must keep them separate, a few possibilities exist. I would lean toward:

%if &mth < 10 %then %let mth = 0&mth;