topic Re: sas in SAS Programming

count values in an observation

vinod4842 — Thu, 30 May 2019 22:47:38 GMT

data ds;
infile datalines;
input name$ a$ b$ c$ d$ e$ f$;
datalines;
vnod yes no no no no yes
jag no yes no yes no yes
raki yes yes yes yes yes no
;
run;

data ds;
infile datalines;
input name$ a$ b$ c$ d$ e$ f$;
datalines;
vnod yes no no no  no yes
jag  no  yes no yes no yes
raki yes yes yes yes yes no
;
run;

i need this dataet as output:

name a b c d e f count(yes)
vnod yes no no no no yes 2
jag no yes no yes no yes 3
raki yes yes yes yes yes no 5

i need to create a column count the row wise 'yes' from a to f columns. kindly help me.

Thank you

Re: sas

PeterClemmensen — Thu, 30 May 2019 20:59:21 GMT

One way

data want(drop=i);  
   set ds;
   array MyArray $ a--f;
   count=0;
   do i=1 to dim(MyArray);
      if MyArray[i]='yes' then count+1;
   end;
run;

Re: sas

r_behata — Thu, 30 May 2019 21:44:49 GMT

data want;
	set ds;

	array cnt{*} a--f;

	count=count(catx('',of cnt[*]),'yes');

run;

Re: count values in an observation

ChrisNZ — Thu, 30 May 2019 22:48:16 GMT

Thread title changed from "sas" to "count values in an observation"

Re: sas

ChrisNZ — Thu, 30 May 2019 22:52:17 GMT

Or:

data WANT;
  set HAVE;
  COUNT=countw(catx(' ',A,B,C,D,E,F), 'yes');
run;

Re: sas

vinod4842 — Fri, 31 May 2019 03:55:19 GMT

its not working correctly friend as this first variable row value is not correct

Re: sas

ChrisNZ — Fri, 31 May 2019 04:11:36 GMT

Oh I misrepresented COUNTW().

This works.

data ds;
  infile datalines;
  input NAME$ A$ B$ C$ D$ E$ F$;
  COUNT=count(catx(' ',of A--F), 'yes'); putlog COUNT=;
datalines;
vnod yes no no no  no yes
jag  no  yes no yes no yes
raki yes yes yes yes yes no
run;

COUNT=2
COUNT=3
COUNT=5

Re: sas

ChrisNZ — Fri, 31 May 2019 04:13:38 GMT

Which does the same as

 COUNT=count(catx(' ',A,B,C,D,E,F), 'yes'); putlog COUNT=;