topic Re: data step in SAS Programming

Add a counter to repeated values

mauri0623 — Tue, 28 May 2019 19:16:03 GMT

Hello,

I have a variable called ODN. The values of ODNs are number such as 101621. If ODN=101621 is happening n times then I need to add a suffix with two values (numeric) - e.g. 10621-01, 10621-02, 10621-03, 10621-04, 10621-05,......10621-n. How can I construct this?

Re: data step

PeterClemmensen — Tue, 28 May 2019 18:55:55 GMT

Here, I assume that your values are grouped

data have;
input ODN $;
datalines;
101621
101621
101621
101623
101623
101623
101622
101622
;

data want(drop=n);
   length ODN $20;
   do n=1 by 1 until (last.ODN);
      set have;
      by ODN notsorted;
      ODN=cats(ODN, '-', put(n, z2.));
      output;
   end;
run;

Re: data step

Reeza — Tue, 28 May 2019 19:15:29 GMT

Numeration by groups is pretty trivial, see the tutorial here.

You can then use the Zd format to add leading zero's and CATX() to combine the data.

data want;
set have;
by ODN;

*resets counter at the first of each group;

if first.OD then count=0;
count+1;

new_ID = catx('-', ODN, put(count, z3.));

run;

@mauri0623 wrote:

Hello,

I have a variable called ODN. The values of ODNs are number such as 101621. If ODN=101621 is happening n times then I need to add a suffix with two values (numeric) - e.g. 10621-01, 10621-02, 10621-03, 10621-04, 10621-05,......10621-n. How can I construct this?

Re: Add a counter to repeated values

Reeza — Tue, 28 May 2019 19:17:11 GMT

FYI - I updated your title to make it more descriptive. This makes it easier for future users to search in the future and find relevant questions and answers. Also, when you post a question, you'll see a 'Related Topics' on the left hand side of the page. In this case several would be exactly what you needed here.

Re: data step

mauri0623 — Fri, 31 May 2019 18:55:07 GMT

Thank you! I accepted as a solution.