topic Re: How to extract "AM" or "PM" from a time variable in SAS Programming

How to extract "AM" or "PM" from a time variable

lydiawawa — Fri, 24 May 2019 17:33:01 GMT

Hi All,

I have a time variable that is in the format of timeampm11.

ex:12:48:06 AM

How do I extract the "AM" from the time value? I have tried the following code none of them worked:

 if index(timestamp, 'AM') then td = "AM"; 
 if scan(timestamp,3," ") eq "AM" then td = "AM";

Thank you!

Re: How to extract "AM" or "PM" from a time variable

Reeza — Fri, 24 May 2019 17:37:30 GMT

If you grab the hour using the hour function and check if that's less than 12 or greater than 12 then it will be pretty easy?

if hour(timestamp) <12 then td='AM';
else if hour(timestamp) >= 12 then td='PM';

Re: How to extract "AM" or "PM" from a time variable

ballardw — Fri, 24 May 2019 17:51:17 GMT

Or an approach with a custom format:

proc format library=work;
picture myampm
low - high ='%p' (datatype=time)
;
run;

data exammple;
 input x :time5.;
 td = put(x,myampm.);
datalines;
00:01
10:15
14:25
23:59
;
run;

Or just use the format as needed with your existing variable.

Re: How to extract "AM" or "PM" from a time variable

Ksharp — Sat, 25 May 2019 11:34:55 GMT

if index(vvalue(timestamp), 'AM') then td = "AM";