topic How do I use Input @'string' right to left? in SAS Programming

How do I use Input @'string' right to left?

phdibart — Mon, 20 May 2019 18:44:48 GMT

Is there anyway to use an input @ statement and have it scan text right to left instead of left to right? I have the following code

data mydata;
infile _filename_ truncover scanover;
input @'string' variable $X.
run;

and am trying to extract X characters before "string," not after, and for the life of me, I cannot figure it out. My program as a whole works if I wanted to extract X characters after the string "text" was found.

Thanks in advance!

Re: How do I use Input @'string' right to left?

Tom — Mon, 20 May 2019 19:06:50 GMT

You cannot use TRUNCOVER and SCANOVER at the same time. I suspect that the last one mentioned is what SAS will use.

Did you try cursor movement commands?

data mydata;
  infile cards ;
  input @'string' +(-16) variable $10. ;
cards;
This line has string in middle
This line has it at the end string 
Short string
does not appear at all
;

You might need to play around to deal with boundary conditions.

data mydata;
  infile cards column=cc ;
  input @'string' @ ;
  found=cc;
  offset = min(cc - length('string') - 10 , cc);
  input @offset variable $10. ;
cards;
This line has string in middle
This line has it at the end string 
Short string
does not appear at all
;

Re: How do I use Input @'string' right to left?

noling — Mon, 20 May 2019 19:04:22 GMT

Check out example 7 - http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000146292.htm

Re: How do I use Input @'string' right to left?

Ksharp — Tue, 21 May 2019 13:45:18 GMT

If you have multiple 'string' in a row, could use PRXNEXT().

data mydata;
infile cards truncover;
input;
p=prxmatch('/.{4}(?=string)/i',_infile_);
if p=0 then p=length(_infile_)+1;
want=substrn(_infile_,p,4);
cards;
This line has string in middle
This line has it at the end string 
Short string
does not appear at all
;

Re: How do I use Input @'string' right to left?

ErikLund_Jensen — Tue, 21 May 2019 16:43:47 GMT

Hi @phdibart

I have always found input with @'string' too inflexible compared to reading the whole line into SAS. Using the automatic variable _infile_ is easier, because you can use the full arsenal of SAS string functions.

This example takes the last 10 characters before 'string' regardless of blanks etc, but it would be just as easy to search for 'string' as a word and extract the last word before that, or whatever would be needed in your case.

File content:

This line has string in middle
This line has it at the end string
Short string
does not appear at all
thisisalongline1234567890stringandmore

%let string = string;
data want (drop=pos);
	infile 'c:\temp\testfile.txt';
	input;
	pos = find(_infile_,"&string",'i');
	if pos > 10 then var = substr(_infile_,pos-10,10);
run;

Re: How do I use Input @'string' right to left?

phdibart — Tue, 21 May 2019 23:08:22 GMT

:edit: I answered my question.

Thank you all for your suggestions. The following code worked.

%let lltract=32.3861,-99.7583;
%let llmsa=32.4101,-99.8114;

filename google url "http://maps.google.com/maps?daddr=&llmsa.%nrstr(&saddr)=&lltract";

data drive (drop = m);
infile google scanover;
llmsa = symget('llmsa');
lltract = symget('lltract');
m = -13;
input @'miles\"'+m miles $34.;
run;

filename google clear;

You can use truncover with scanover. See example #3. http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a000146932.htm