topic Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python) in SAS Programming

Multiply vector * data with base sas (a(vector)*b(dataset) in python)

carles — Mon, 20 May 2019 16:00:39 GMT

Hello Community :),

I am trying to do the following multiplication in SAS and I am getting in trouble. I want to mention that what I call as vector is indeed a dataset with one column in SAS:

I would like to do it with base SAS, but I am getting problems with indices and colnames

DATA WORK.dataset;
  INPUT      X Y;
   datalines;
1 4
2 3
3 2

;
run;
DATA WORK.vector;
  INPUT      vector;
   datalines;
2
3

;
run;

Thank you for the help in advanced,

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

PeterClemmensen — Mon, 20 May 2019 15:25:19 GMT

First of all, why don't you want to so this in IML, when this clearly is a Matrix/Vector problem?

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

carles — Mon, 20 May 2019 15:30:03 GMT

I do not have access to the iml package. That is why, else it would be quite straightforward.

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

Tom — Mon, 20 May 2019 15:35:32 GMT

Do you have SAS/STAT licensed? There are many clever ways to use the scoring functionality to implement essentially matrix multiplication.

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

PaigeMiller — Mon, 20 May 2019 15:36:22 GMT

Without access to IML, you can do this type of vector multiplication using PROC SCORE (but you'd have to have a license for SAS/STAT). Here is an example: https://documentation.sas.com/?cdcId=pgmmvacdc&cdcVersion=9.4&docsetId=statug&docsetTarget=statug_score_examples03.htm&locale=en

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

Tom — Mon, 20 May 2019 15:36:37 GMT

Pictures are REALLY hard to code from.

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

Tom — Mon, 20 May 2019 16:11:18 GMT

Are you sure that is the output you want?

If so then explain what type of multiplication you are doing.

Here is what we get if we do matrix multiplication in IML.

proc iml;
x={2 3};
y={1 4,2 3,3 2};
print x;
print y;
z=y*x;
print z;
quit;

Which you can mimic in data step.

data want;
  set dataset;
  array row x y ;
  Z=.;
  do i=1 to dim(row);
    set vector point=i;
    Z=sum(Z,row[i]*vector);
  end;
  keep Z ;
run;
proc print data=want; run;

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

Astounding — Mon, 20 May 2019 20:26:30 GMT

To mimic this in a DATA step, I think it's fastest to in effect transpose the vector:

data want;
   array v {99} _temporary_;
   if _n_=1 then do until (done);
      set vector end=done;
      n_terms + 1;
      v{n_terms} = vector;
   end;
   drop n_terms k vector;
   set dataset;
   array vals {2} X Y;
   total = 0;
   do k=1 to n_terms;
      total + vals{k} * v{k};
   end;
run;

It's not 100% clear whether you actually want something slightly different inside the loop, such as forgetting about TOTAL and instead calculating:

vals{k} = vals{k} * v{k};

Re: Multiply vector * data with base sas (a(vector)*b(dataset) in python)

Ksharp — Tue, 21 May 2019 14:23:28 GMT

DATA WORK.dataset;
  INPUT      X Y;
   datalines;
1 4
2 3
3 2

;
run;
DATA WORK.vector;
  INPUT      vector;
   datalines;
2
3

;
run;

proc transpose data=dataset(obs=0) out=temp;
var _all_;
run;
data key;
 merge temp vector;
 key=cats(_name_,'=',_name_,'*',vector,';');
run;

data want;
 set key end=last;
 if _n_=1 then call execute('data want;set dataset;');
 call execute(key);
 if last then call execute('run;');
run;