topic Re: Learning MACROS...would like sample coding as reference in SAS Programming

Learning MACROS...would like sample coding as reference

KyleS83 — Sun, 05 Jun 2011 04:40:29 GMT

suppose I have 5-6 different SAS data sets stored in my C: drive (example c:/SASData)

What would be an effective macro that I could use that would display (using proc print) all of the data sets in that C: folder?

Thanks for the help!

Re: Learning MACROS...would like sample coding as reference

ArtC — Sun, 05 Jun 2011 05:10:50 GMT

here is a possible solution:
[pre]%macro printit(dsn=);
title1 Printing &dsn;
proc print data=&dsn(obs=5);
run;
%mend printit;

%macro getdatalist(lib=);
%local count i;
proc sql noprint;
select distinct memname
into :mem1 - :mem&sysmaxlong
from dictionary.members
where libname=upcase("&lib");
quit;
%let count = &sqlobs;
%do i = 1 %to &count;
%printit(dsn=&lib..&&mem&i);
%end;
%mend getdatalist;
%getdatalist(lib=sasclass)
[/pre]

Re: Learning MACROS...would like sample coding as reference

johnP — Sun, 05 Jun 2011 23:11:07 GMT

/* first assign your folder to a libname */
libname newLib 'c:/SASData';

/* to just show dataset names in ouput window */
proc sql;
select memname
from
dictionary.members
where libname='newLib'
;
quit;

/* or to put the dataset names into a dataset and then view with proc print */
proc sql;
create table newDataset as
select memname
from
dictionary.members
where libname='newLib'
;
quit;
proc print data=newDataset;
run;

Re: Learning MACROS...would like sample coding as reference

Ksharp — Tue, 07 Jun 2011 07:11:39 GMT

Just as Arthur.Carpenter 's code.But I used call execute() which is interface of macro facility with dataset.If you like.
[pre]

libname mylib 'c:\temp';
data _null_;
set sashelp.vtable(where=(libname='MYLIB'));
call execute('proc print data=mylib.'||strip(memname)||';');
call execute('run;');
run;
[/pre]

Ksharp

Re: Learning MACROS...would like sample coding as reference

RMP — Tue, 07 Jun 2011 08:27:55 GMT

if you are only interested in the characteristics of the datasets and not the physical data then you can use

proc contents data=lib._all_;
run;