topic Re: combine single letters in strings in SAS Programming

combine single letters in strings

somebody — Mon, 20 May 2019 10:26:15 GMT

I have a variable that contains company names. However, if a company name contains abbreviation, it creates space between the letters. For example, instead of "ACCO Brand Corp", the variable is " A C C O BRAND CORP". My question is, is there a way to group the ACCO together? Thanks

Re: combine single letters in strings

Amir — Mon, 20 May 2019 10:56:10 GMT

Please share the code you are referring to when you say "it creates space between the letters".

1) Is the original data in a SAS data set?

2) Is the output data in a SAS data set?

3) Please share the log with any messages.

4) Please share some code and that can be run as is to demonstrate the problem, e.g., using dataines in a data step.

Thanks,

Amir.

Re: combine single letters in strings

FreelanceReinh — Mon, 20 May 2019 10:59:57 GMT

Hi @somebody,

Try this:

data have;
company=" A C C O BRAND CORP";
run;

data want;
set have;
company=left(prxchange('s/(?<=(\b[A-Z])) (?=([A-Z]\b))//o',-1,propcase(company)));
run;

The Perl regular expression deletes single blanks which are preceded by a single uppercase letter (which is separated from preceding text, if any, by a word boundary) and followed by another single uppercase letter (which is separated from subsequent text, if any, by a word boundary).

Re: combine single letters in strings

Kurt_Bremser — Mon, 20 May 2019 11:04:28 GMT

With "conventional" data step means:

data test;
mystr = ' A C C O BRAND CORP';
*mystr = left(mystr);
i = 2;
do until (i >= length(mystr) or x>10);
  if substr(mystr,i,1) ne ' ' and substr(mystr,i-1,1) = ' ' and substr(mystr,i+1,1) = ' '
  then do;
    if i > 2
    then mystr = substr(mystr,1,i-2) !! substr(mystr,i);
	else mystr = substr(mystr,2);
  end;
  else i + 1;
end;
run;

Re: combine single letters in strings

Ksharp — Tue, 21 May 2019 15:03:28 GMT

data test;
mystr = 'A C C O BRAND CORP';
temp=prxchange('s/(\w{2,})/ $1 /',-1,mystr);
want=compbl(prxchange('s/ (\w) /$1/',-1,temp));
run;

Re: combine single letters in strings

somebody — Thu, 23 May 2019 00:08:48 GMT

Thanks, your method works too. just one minor comment is that the result has a space at the start of the string.

Re: combine single letters in strings

Ksharp — Thu, 23 May 2019 11:26:05 GMT

Add one more function LEFT() around it .