topic How to add column with the table name in SAS Programming

How to add column with the table name

priya_05 — Sun, 05 May 2019 19:57:52 GMT

Hello,

i am new to sas and i have one problem.

I have employee table

proc sql;
create table WORK.EMPLOYEE( 
first_name char(50),
last_name char(50) 
);

insert into WORK.EMPLOYEE
VALUES('PINTTO','KARLSSON')
VALUES('NATASHA','JOHANSSON')
VALUES('HARRY','BRUUN');

QUIT;

proc SQL;
CREATE TABLE WORK.TEMP AS
SELECT FIRST_NAME, LAST_NAME FROM WORK.EMPLOYEE;
QUIT;

from this i get the following output

Now i want to add third column which shows the table name "Employee" in front of every record

Could you please help me with this

Re: How to add column with the table name

novinosrin — Sun, 05 May 2019 20:28:48 GMT

Use Datastep witn INDSNAME= set option

data temp;
set employee indsname=name;
tablename=scan(name,2);
run;

Re: How to add column with the table name

PeterClemmensen — Sun, 05 May 2019 20:42:04 GMT

Welcome to the SAS Communities 🙂

Read this: Where did it come from? Adding the source of each observation to a SAS data set

Re: How to add column with the table name

PGStats — Sun, 05 May 2019 21:44:36 GMT

Do you mean something like this?

proc sql;
alter table Employee
add table_name char(16) ;
update employee set table_name="Employee";
quit;

Re: How to add column with the table name

Tom — Mon, 06 May 2019 03:06:55 GMT

The INDSNAME option on the SET statement will help with doing something like that.

data EMPLOYEE ;
  length first_name $50 last_name $50 ;
  infile cards dsd dlm='|' truncover ;
  input first_name last_name;
cards;
PINTTO|KARLSSON
NATASHA|JOHANSSON
HARRY|BRUUN
;

data temp;
  length table_name indsname $41 ;
  set employee indsname=indsname;
  table_name=indsname;
run;

proc print data=temp;
run;

Re: How to add column with the table name

priya_05 — Thu, 09 May 2019 10:30:52 GMT

Thank you so much. It works