topic Re: How to send an email from SAS only if data exists? in SAS Programming

How to send an email from SAS only if data exists?

jerathashutosh — Mon, 29 Apr 2019 15:43:11 GMT

Hi,

I have a daily email that goes out, but i want to send the email only when data exists. Currently it sends an email no matter if the data exists or not.

Currently i make a dataset with the desired data and then i run this code to send an email:

filename outbox email
to=("abc@gmail.com")
type='text/html'
subject="Today's Details"
from='abc@gmail.com';
ods html body=outbox;
proc print data= WORK.EMAIL;
run;
ods html close;

is there a way i can do something like:

if count is not null then (

filename outbox email
to=("abc@gmail.com")
type='text/html'
subject="Today's Details"
from='abc@gmail.com';
ods html body=outbox;
proc print data= WORK.EMAIL;
run;
ods html close;

)

else exit;

Thanks.

Ashu

Re: How to send an email from SAS only if data exists?

Tom — Mon, 29 Apr 2019 16:00:05 GMT

You can use macro code to generate SAS code. With latest version of SAS you can even using simple %IF/%THEN/%DO statements in a regular SAS program. For older versions (or more complex macro logic) you will need to wrap the code into a macro definition.

data _null_;
  call symputx('nobs',nobs);
  stop;
  set work.email nobs=nobs;
run;

%if (&nobs) %then %do;

filename outbox email
  to=("abc@gmail.com")
  type='text/html'
  subject="Today's Details"
  from='abc@gmail.com'
;
ods html body=outbox;
proc print data= WORK.EMAIL;
run;
ods html close;

%end;

Re: How to send an email from SAS only if data exists?

jerathashutosh — Tue, 30 Apr 2019 02:26:51 GMT

works like a charm!

Thanks Tom.

Ashu

Re: How to send an email from SAS only if data exists?

ChrisNZ — Tue, 30 Apr 2019 03:44:38 GMT

Or, if you want to avoid writing macros:

data _null_;
  if NOBS then call execute(catt(
     "filename OUTBOX email            "
   , " to=('abc@gmail.com')            "
   , " type='text/html'                "
   , " subject=""Today's Details""     "
   , " from='abc@gmail.com' ;          "
   , "ods html body=OUTBOX;            "
   , "proc print data=WORK.EMAIL; run; "
   , "ods html close;                  " 
   , "filename OUTBOX clear;           " ));
  stop;
  set WORK.EMAIL nobs=NOBS;
run;

Re: How to send an email from SAS only if data exists?

jerathashutosh — Thu, 02 May 2019 20:21:44 GMT

this works perfectly as well! 😄

Thanks ChrisNZ.

Ashu