topic extract specific multiple numbers from String with delimiters in SAS Programming

extract specific multiple numbers from String with delimiters

mandonium — Wed, 24 Apr 2019 01:02:33 GMT

I need to extract specific numbers from a variable (cmaeno). Some records have one number, others have multiple numbers I need. The numbers that I need are in the "( )" :

I do not no where to start syntax wise. Any help would be greatly appreciated.

Re: extract specific multiple numbers from String with delimiters

PGStats — Wed, 24 Apr 2019 01:37:31 GMT

Regular expression matching is well suited for this kind of work:

data want;
if not prxId then prxId + prxParse("/\((\d+)\)/");
set have;
start = 1;
stop = length(cmaeno);
call prxNext(prxID, start, stop, cmaeno, pos, len);
do while (pos > 0);
    cmaenum = input(prxPosn(prxId, 1, cmaeno), best.);
    output;
    call prxNext(prxID, start, stop, cmaeno, pos, len);
    end;
drop prxId start stop pos len;
run;

EDIT Code corrected, thanks to example provided by @Patrick .

Re: extract specific multiple numbers from String with delimiters

Patrick — Wed, 24 Apr 2019 01:27:07 GMT

@mandonium

Basically the same than what @PGStats already posted while I was still coding.

data have;
  varWithText='abc (5) 23xx(9)abc94(345)4 73xy';
  output;
  stop;
run;

data want(drop=_:);
  set have;
  if _n_=1 then
    do;
      _expID = prxparse('/(?<=\()\d+(?=\))/');
      retain _expID;
    end;
  _start = 1;
  _stop = length(varWithText);

  /* Use PRXNEXT to find the first instance of the pattern, */
  /* then use DO WHILE to find all further instances.       */
  /* PRXNEXT changes the start parameter so that searching  */
  /* begins again after the last match.                     */
  call prxnext(_expID, _start, _stop, varWithText, _pos, _len);

  do while (_pos > 0);
    found = substr(varWithText, _pos, _len);
/*    put found= _pos= length=;*/
    output;
    call prxnext(_expID, _start, _stop, varWithText, _pos, _len);
  end;
run;

Code based on sample found here:

http://support.sas.com/documentation/cdl/en/lrdict/64316/HTML/default/viewer.htm#a002295965.htm

Re: extract specific multiple numbers from String with delimiters

mandonium — Wed, 24 Apr 2019 01:31:15 GMT

I'm getting a blank "cmaenum" column and a blank "text" column:

data cm02;
if not prxId then prxId + prxParse("/\((\d+)\)/");
set toc6.cm;
start = 1;
stop = length(cmaeno);
call prxNext(prxID, start, stop, cmaeno, pos, len);
do while (pos > 0);
    cmaenum = input(substr(text, pos, len), best.);
    output;
    call prxNext(prxID, start, stop, cmaeno, pos, len);
    end;
drop prxId start stop pos len;
run;

Here's what I get:

Re: extract specific multiple numbers from String with delimiters

PGStats — Wed, 24 Apr 2019 01:40:38 GMT

Please check corrected version above.

Re: extract specific multiple numbers from String with delimiters

mandonium — Wed, 24 Apr 2019 01:46:35 GMT

Thank you! The corrected code worked perfectly. 🙂