topic Re: Apply the user defined format to the variable within the datastep if variable exists in SAS Programming

Apply the user defined format to the variable within the datastep if variable exists

Sami1234 — Fri, 12 Apr 2019 10:40:17 GMT

Dear Experts,

Would there be any way or function to apply the user-defined format to the variable if exists/present in the dataset? for example something like below.

Data test1;

set test;

if var1 exists then do;

format var1 format1;

end;

if var2 exists then do;

format var2 format2;

end;

if var3 exists then do;

format var3 format3;

end;

run;

Thank you!

Re: Apply the user defined format to the variable within the datastep if variable exists

SASKiwi — Fri, 12 Apr 2019 10:51:24 GMT

The FORMAT statement is not an executable statement so you would have to use macro code to write this statement if the variable exists or not write it at all if not.

Re: Apply the user defined format to the variable within the datastep if variable exists

Sami1234 — Fri, 12 Apr 2019 10:54:10 GMT

Thanks for replying.

Would you please give me a little example?

Re: Apply the user defined format to the variable within the datastep if variable exists

Astounding — Fri, 12 Apr 2019 13:34:54 GMT

Maybe, in some cases. For example:

format religion: relfmt.;

This statement affects all variable names that begin with "religion". If there are none, it affects no variables but might issue a note or even a warning. If there is 1 named "religion" you get the right result. But if there are multiple such variables you get the wrong result.

Re: Apply the user defined format to the variable within the datastep if variable exists

Kurt_Bremser — Fri, 12 Apr 2019 13:49:52 GMT

If you only want to assign formats, without other changes to the data, use proc datasets.

Set up a control table:

data control;
input varname :$32. fmtname :$32.;
datalines;
var1 format1.
var2 format2.
var3 format3.
;
run;

Check which variables are present:

proc sql;
create table correction as 
select a.varname, a.fmtname
from control a, dictionary.columns b
where upcast(a.varname) = upcast(b.name) and
  b.libname = "WORK" and b.memname = "TEST";
quit;

Dynamically create the code for proc datasets:

data _null_;
set correction end=eof;
if _n_ = 1 then call execute("
  proc datasets library=WORK noprint;
  modify TEST;
  format 
");
call execute(catx(" ",varname,fmtname, ""));
if eof then call execute("
  ;
  quit;
");
run;

Re: Apply the user defined format to the variable within the datastep if variable exists

Sami1234 — Mon, 15 Apr 2019 14:01:57 GMT

Thank you so much, it works perfectly fine.