topic Read a Variable Value into a Macro Variable in SAS Programming

Read a Variable Value into a Macro Variable

CurtisSmithDCAA — Tue, 09 Apr 2019 18:52:32 GMT

I need to read the value of a variable into a macro variable and then in the same data step use the macro variable as the upper limit in a do loop. My code is as follows:

data work.test;
set in.test_data;
call symput('mqty',trim(Order_Quantity));
put "Quantity = &mqty.";
do i=1 to "&mqty.";
output;
end;
run;

But, the symput only processes the last row in the data set, so it uses that value in each iteration of the do loop.

Any suggestions?

Re: Read a Variable Value into a Macro Variable

Kurt_Bremser — Tue, 09 Apr 2019 18:59:10 GMT

Why not do

data work.test;
set in.test_data;
do i=1 to order_quantity;
  output;
end;
run;

Re: Read a Variable Value into a Macro Variable

CJac73 — Wed, 10 Apr 2019 03:02:39 GMT

What @KirkBresmer said. You can still do the macro var, but it is the same value as order_quantity

Re: Read a Variable Value into a Macro Variable

ScottBass — Wed, 10 Apr 2019 04:38:39 GMT

I need to read the value of a variable into a macro variable and then in the same data step use the macro variable as the upper limit in a do loop.

This will never work. Read the macro doc to understand the difference between compile time vs. run time execution.

In your example:

data work.test;
set in.test_data;
call symput('mqty',trim(Order_Quantity));
put "Quantity = &mqty.";
do i=1 to "&mqty.";
output;
end;
run;

&mqty (lines 4 & 5) is evaluated before the data step starts execution.

Also, I recommend call symputx over call symput.

Re: Read a Variable Value into a Macro Variable

Tom — Wed, 10 Apr 2019 05:30:52 GMT

There is no need in your example since you already have the value in the dataset.

If you did need to read the value of a macro variable dynamically then use SYMGET() or SYMGETN() function.

Try this program.

%let x1=5;
%let x2=3;
data test;
do row=1 to 2;
  do obs=1 to symgetn(cats('x',row));
    output;
  end;
end;
run;

Re: Read a Variable Value into a Macro Variable

Astounding — Wed, 10 Apr 2019 05:34:10 GMT

do i=1 to symgetn('mqty');

Re: Read a Variable Value into a Macro Variable

ScottBass — Wed, 10 Apr 2019 06:02:46 GMT

@Tom and @Astounding are very smart SAS professionals, and I bow to their expertise. They've both helped me more times than I can count (although that presumes I can count very high).

However, in this instance, I'll point out that I feel their examples are illustrative only, just so you understand the concept of symget and symgetn. I don't think using symget is the approach you should be using in your example. (Actually, Tom made it clear that it was just an example).

If you find yourself loading a data step variable into a macro variable (call symput), then wanting to reference that macro variable in the same data step (symget), 99.99% of the time you should just use the data step variable instead. Moving data to/from the macro symbol table is much slower than using data in the PDV/data step.

In summary, use @Kurt_Bremser 's approach.

Re: Read a Variable Value into a Macro Variable

Kurt_Bremser — Wed, 10 Apr 2019 06:24:49 GMT

And if you need to keep values across observations, the data step provides multiple tools for this:

lag() functions
retained variables
temporary arrays
hash objects

which will all perform better than invoking the macro processor repeatedly while the step is running.