topic Re: Resolving macro variables in SAS Programming

Resolving macro variables

nimmy_mj — Sun, 31 Mar 2019 13:42:27 GMT

Hi, I have the below code:

%let a=b;
%let b=c;
%let c=a;

%let d=&c; %let e=&&c; %let f=&&&c; %let g=&&&&c; %let h=&&&&&c; %let i=&&&&&&c;

data test;
check="&d";output;
check="&e";output;
check="&f";output;
check="&g";output;
check="&h";output;check="&i";output;
run;

d resolves to a

e resolves to a

f resolves to b

g resolves to a

h resolves to b

I resolves to b

Could you please explain how this is happening? According to my logic, g should resolve to b and h should resolve to c and I to c.

If there is a diagrammatical representation, it will be helpful.

Re: Resolving macro variables

data_null__ — Sun, 31 Mar 2019 13:55:36 GMT

Re: Resolving macro variables

Shmuel — Sun, 31 Mar 2019 15:01:11 GMT

Pay attention that any && are in first step replaced by &.

&&&X = (&&) &X - (1) resolve &X then resolve &(resolved value)

&&&&X = (&&)(&&)x = &&X = &X

I hope that explains the behavior.

Re: Resolving macro variables

Tom — Sun, 31 Mar 2019 15:42:25 GMT

Turn the SYMBOLGEN option and see for yourself what is happening.

1     %let a=b;
2     %let b=c;
3     %let c=a;
4     options symbolgen;
5     %let d=&c;
SYMBOLGEN:  Macro variable C resolves to a
6    %let e=&&c;
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable C resolves to a
7    %let f=&&&c;
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable C resolves to a
SYMBOLGEN:  Macro variable A resolves to b
8    %let g=&&&&c;
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable C resolves to a
9    %let h=&&&&&c;
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable C resolves to a
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable A resolves to b
10   %let i=&&&&&&c;
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  && resolves to &.
SYMBOLGEN:  Macro variable C resolves to a
SYMBOLGEN:  Macro variable A resolves to b
11   options nosymbolgen;

Re: Resolving macro variables

ballardw — Mon, 01 Apr 2019 16:42:09 GMT

You might be better off using %PUT statements to determine the evaluation of your data. The data step you use will set the length of the variable CHECK to the length of the first variable. Which could result in truncation. Please see:

%let a=b;
%let b= somethinglonger;

data test;
check="&a.";output;
check="&b.";output;
run;
proc print data=test;
run;

compare with:

%put A is: &a.;
%put B is: &b.;