topic Re: Proc transpose not keeping all decimal values in SAS Programming

Proc transpose not keeping all decimal values

mahi2pal — Fri, 29 Mar 2019 14:05:00 GMT

data Abun_dw20d_summary ;       informat bins $30.; format bins $30.; length bins $30.;
   input bins $ CM1DW20D CM3DW20D CW1DW20D ODWD W1DW4D;
   datalines;         
Acinetobacter 2477.123456789 195  163 45 77
Actinoalloteichus 2431 220  198 69.123456789 6774
Bacillus 2456 173  155 78 785
Bletilla 2412 135  116.123456789 45 123;   
run;


proc transpose data=Abun_dw20d_summary out=bint;
    var _all_;
    by bins;
run;

My decimals are getting truncated in output dataset, can anyone help me on this?

Re: Proc transpose not keeping all decimal values

data_null__ — Fri, 29 Mar 2019 14:10:07 GMT

@mahi2pal wrote:
data Abun_dw20d_summary ; informat bins $30.; format bins $30.; length bins $30.; input bins $ CM1DW20D CM3DW20D CW1DW20D ODWD W1DW4D; datalines; Acinetobacter 2477.123456789 195 163 45 77 Actinoalloteichus 2431 220 198 69.123456789 6774 Bacillus 2456 173 155 78 785 Bletilla 2412 135 116.123456789 45 123; run; proc transpose data=Abun_dw20d_summary out=bint; var _all_; by bins; run;

My decimals are getting truncated in output dataset, can anyone help me on this?

Did you notice this?

NOTE: Numeric variables in the input data set will be converted to character in the output data set.

SAS used a default format I think BEST12.

If you want more decimal places use a different format.

Re: Proc transpose not keeping all decimal values

Cynthia_sas — Fri, 29 Mar 2019 14:33:02 GMT

Hi:

Providing a format seems to take care of the issue for me:

Hope this helps,

cynthia

Re: Proc transpose not keeping all decimal values

mahi2pal — Fri, 29 Mar 2019 18:14:19 GMT

Where do give the format?

Re: Proc transpose not keeping all decimal values

Cynthia_sas — Fri, 29 Mar 2019 21:10:13 GMT

It is highlighted in yellow in the screen shot in my previous posting.
Cynthia

Re: Proc transpose not keeping all decimal values

Tom — Fri, 29 Mar 2019 23:23:16 GMT

1) Don't include the character variables in the VAR statement and PROC TRANSPOSE will not convert your numeric variables to character.

2) If you must include the character variables then attach a format to the numeric variables that is long enough.

Example:

data have ;       
  length bins $30.;
  input bins CM1DW20D CM3DW20D ;
datalines;         
Acinetobacter 2477.123456789 195 
Bletilla 2412 116.123456789
;
proc print width=min; title 'HAVE';
  format _numeric_ best32.;
run;

proc transpose data=have out=want1;
  by bins;
run;
proc print width=min; title 'WANT1';
  format _numeric_ best32.;
run;
proc transpse data=have out=want2;
  by bins;
  var _all_;
  format _numeric_ best32.;
run;
proc print width=min; title 'WANT2'; 
run;
title;

HAVE
Obs    bins                   CM1DW20D         CM3DW20D

 1     Acinetobacter    2477.123456789              195
 2     Bletilla                   2412    116.123456789

WANT1
Obs    bins              _NAME_               COL1

 1     Acinetobacter    CM1DW20D    2477.123456789
 2     Acinetobacter    CM3DW20D               195
 3     Bletilla         CM1DW20D              2412
 4     Bletilla         CM3DW20D     116.123456789

WANT2
Obs    bins             _NAME_                    COL1

 1     Acinetobacter    bins        Acinetobacter
 2     Acinetobacter    CM1DW20D                      2477.123456789
 3     Acinetobacter    CM3DW20D                                 195
 4     Bletilla         bins        Bletilla
 5     Bletilla         CM1DW20D                                2412
 6     Bletilla         CM3DW20D                       116.123456789