topic Re: unify strings to 'UK'? in SAS Programming

unify strings to 'UK'?

Alexxxxxxx — Wed, 27 Mar 2019 15:31:01 GMT

Dear all,

How can I unify below strings to 'UK'?

data have ;
  infile datalines truncover;
  input name $100.;
  datalines;
ABC (U.K.)
ABC (U K )
ABC [U.K.]
ABCU. K.  /*this one should not be unified*/
ABC {U. K.}
ABC 'U K'
AB C U K
;
run;

I expect to get

ABC (UK)
ABC (UK)
ABC [UK]
ABCU. K.  /*this one should not be unified*/
ABC {UK}
ABC 'UK'
AB C UK

Could you please give me some suggestions about this?

thanks in advance

Re: unify strings to 'UK'?

andreas_lds — Wed, 27 Mar 2019 15:15:35 GMT

Please post what you expect as output for each observation.

Re: unify strings to 'UK'?

gamotte — Wed, 27 Mar 2019 15:35:06 GMT

Hello,

You might have to adapt a bit depending on the specific behavior you want.

data want;
set have;
unif=prxchange("s/\bU\b[. ]+\bK\b[. ]+/UK/i",-1,name);
run;

Edit : I slighly modified the regular expression after your reply to @andreas_lds

Re: unify strings to 'UK'?

Alexxxxxxx — Wed, 27 Mar 2019 15:31:25 GMT

thanks

I expect to get

ABC (UK)
ABC (UK)
ABC [UK]
ABCU. K.  /*this one should not be unified*/
ABC {UK}
ABC 'UK'
AB C UK

Re: unify strings to 'UK'?

Alexxxxxxx — Wed, 27 Mar 2019 16:41:54 GMT

Dear @gamotte

thanks for your code,

but the

ABC 'U K'

is not been processed.

Besides, Could you please introduce some manual to learn the meaning of following codes

s/\bU\b[. ]+\bK\b[. ]+/UK/i

and what is the type/name of this code?(i.e., how do you call this code?)

Re: unify strings to 'UK'?

gamotte — Wed, 27 Mar 2019 16:54:56 GMT

Look for "perl regexp" in google.

Here \b means a word boundary.

[. ] means a space or a period

[. ]+ means one or more spaces/periods

U and K are the letters U and K

In ABC 'U K', K is followed by ' and so does not match the regexp.

You can drop the final [. ]+

s/\bU\b[. ]+\bK\b/UK/i

Re: unify strings to 'UK'?

ChrisNZ — Thu, 28 Mar 2019 22:12:19 GMT

I would run this to cover more cases:

UNIF=prxchange("s/ [^\w\d]*U[^\w\d]+K[^\w\d]*$/ UK/i",1,NAME);

This cleans:

space

followed by optional non-alphanumerics

followed by U

followed by non-alphanumerics

followded by K

followed by optional non-alphanumerics

then end of string

The final i make this case insensitive, which may not be what you want.

Re: unify strings to 'UK'?

Ksharp — Thu, 28 Mar 2019 14:15:45 GMT

data have ;
  infile datalines truncover;
  input name $100.;
  datalines;
ABC (U.K.)
ABC (U K )
ABC [U.K.]
ABCU. K.  /*this one should not be unified*/
ABC {U. K.}
ABC 'U K'
AB C U K
;
run;

data want;
 set have;
 pid=prxparse('/\bu\W+k\b/i');
 call prxsubstr(pid,name,p,l);
 if p>0 then do; 
 if substr(name,p+l,1) in (' ' '.') then l=l+1;
 substr(name,p,l)= 'UK'; 
 end;
run;
proc print;run;