topic Re: create a folder(Directory) for each car maker in SAS Programming

create a folder(Directory) for each car maker

Ronein — Sun, 17 Mar 2019 06:19:44 GMT

Hello

I want to create a folder(Directory) for each car maker (SAShelp.cars data set)

Name of the field in (SAShelp.cars data set is "Make"

What is the way to do it please?

Re: create a folder(Directory) for each car maker

andreas_lds — Sun, 17 Mar 2019 06:32:41 GMT

Sort by Make, use "by make" in a data step. On first.Make create the directory using function dcreate.

Re: create a folder(Directory) for each car maker

Ronein — Sun, 17 Mar 2019 06:41:48 GMT

I know to create one NewDirectory.

data _null_;
NewDirectory=dcreate("RRRT1","path");
run;

However, I dont know how to do it for multiple.

Should I use macro?

Can you show the code please?

Re: create a folder(Directory) for each car maker

Kurt_Bremser — Sun, 17 Mar 2019 07:04:54 GMT

Read @andreas_lds post again, thoroughly.

You run a data step off your dataset, use by, and execute dcreate at the group change.

Re: create a folder(Directory) for each car maker

Ronein — Sun, 17 Mar 2019 07:20:32 GMT

Thank you.

I have tried but still I got only one folder called "make" instead of 38 folders...

 PROC SQL;
	create table bbbb  as
	select distinct Make as Make 	   
	from sashelp.cars 
	order by Make
;
QUIT;

data _null_;
NewDirectory=dcreate("sashelp.cars","/path/");
run;

Data cccc;
set bbbb;
by Make;
NewDirectory=dcreate("Make","/path/sashelp.cars");
Run;

Re: create a folder(Directory) for each car maker

andreas_lds — Sun, 17 Mar 2019 07:28:14 GMT

Remove the quotes from "Make l" if you want the value in Make as directory name.

Re: create a folder(Directory) for each car maker

andreas_lds — Sun, 17 Mar 2019 07:33:49 GMT

Untested code - without group-processing:
Proc sort data=sashelp.cars out=work.make(keep=Make) nodupkey;
By make;
Run;
Data _null_;
Set Make;

Length NewDirectory $ 200;
Retain NewDirectory;

If _n_ =1 then do;
NewDirectory=dcreate("sashelp.cars","/path/");
End;

MakeDir = dcreate(Make, NewDirectory);
Run;

Re: create a folder(Directory) for each car maker

PeterClemmensen — Sun, 17 Mar 2019 07:45:33 GMT

proc sort data=sashelp.cars out=cars;
   by Make;
run;

data _null_;
   set cars;
   by Make;
   if first.Make then do;
      NewDirectory=dcreate(Make,"c:\");
   end;
run;