topic Creating a do loop for multiple records in SAS Programming

Creating a do loop for multiple records

jmmedina25 — Sun, 10 Mar 2019 02:19:08 GMT

Hi all. I'm looking to create a variable that will flag weight-changes between weeks that are greater/ less than 8 pounds. I think a do loop would be appropriate but I'm not exactly sure how because there are multiple entries per ID number...Here's the layout of my data:

ID Date Weight

1 6/6 130

1 6/13 135

1 6/21 128

2 6/6 149

2 6/13 151

2 6/21 146

...

Thanks for your help!

Re: Creating a do loop for multiple records

Astounding — Sun, 10 Mar 2019 03:46:55 GMT

The DATA step functions like a DO loop automatically, reading one observation then the next, then the next. Try it this way:

data want;
set have;
by id;
change = dif(weight);
if first.id=0 then do;
if change > 8 then flag ="+";
else if change < -8 then flag ="-";
end;
run;

Re: Creating a do loop for multiple records

PGStats — Sun, 10 Mar 2019 04:10:55 GMT

Assuming that each record represents a week and that data is sorted:

data have;
input ID Date $ Weight;
datalines;
1           6/6                130
1           6/13              135
1           6/21              118
2           6/6                149
2           6/13              151
2           6/21              146
;

data want;
do until(last.id);
    set have; by id;
    if not first.id then flag = abs(Weight-lastWeekWeight) > 8;
    output;
    lastWeekWeight = weight;
    end;
drop lastWeekWeight;
run;

proc print; run;

                        Obs    ID    Date    Weight    flag

                         1      1    6/6       130       .
                         2      1    6/13      135       0
                         3      1    6/21      118       1
                         4      2    6/6       149       .
                         5      2    6/13      151       0
                         6      2    6/21      146       0

Re: Creating a do loop for multiple records

jmmedina25 — Tue, 12 Mar 2019 16:14:58 GMT

This code worked well; thank you!