topic Re: macro not resolved in SAS Programming

macro not resolved

liyongkai800 — Thu, 07 Mar 2019 19:58:46 GMT

Hi folks,

I store several lists in a series of macros. However, the macros are not resolved. Anything wrong here? Thanks

data ParamData;
input x @@;
datalines;
1 2 3 4 5
;

%macro whatever;
%do i=1 %to 5;
proc sql ;
select x into :ParamList&i separated by ' '
from ParamData where x<&i+1;
quit;
%end;
%mend;

%whatever;

%put ParamList = &ParamList1;

Re: macro not resolved

Kurt_Bremser — Thu, 07 Mar 2019 20:08:07 GMT

The macro variables are local to the macro. Use %global.

And use the proper methods for posting code and logs. "Little running man" for code, {i} for logs. The main posting window scrambles the text.

Re: macro not resolved

PaigeMiller — Thu, 07 Mar 2019 20:12:56 GMT

%macro whatever;
    %do i=1 %to 5;
    %global paramlist&i;
    proc sql ;
         select x into :paramList&i separated by ' '
          from ParamData where x<&i+1;
    quit;
    %end;
%mend;

%whatever

You need the %global command. Otherwise, macro variables defined inside a macro cannot be used outside the macro.

Furthermore, in the future, please paste your SAS code into the window that appears when you click on the "running man" icon, and then you won't have smiley faces in your SAS code.