topic Re: multiple one-way freq tables via proc tabulate in SAS Programming

multiple one-way freq tables via proc tabulate

Ronein — Mon, 04 Feb 2019 06:25:55 GMT

Hello

I am trying to create multiple one-way freq tables via proc tabulate.

For each table I want to create a separate title.

Why is it not working???

proc tabulate data=sashelp.heart;
  class chol_status bp_status  sex;

  title 'chol_status field';
  table chol_status='' All,n='people' pctn='%people'*f=pctfmt./box='cholesterol';

  title 'bp_status field';
  table bp_status='' All,n='people' pctn='%people'*f=pctfmt./box='BP ';

  title 'sex field';
  table sex='' All,n='people' pctn='%people'*f=pctfmt./box='Gender';
run;

Re: multiple one-way freq tables via proc tabulate

singhsahab — Mon, 04 Feb 2019 10:26:10 GMT

Hi Robin,

In place of title you can use pretext style options in table statement.

proc tabulate data=sashelp.heart;
  class chol_status bp_status  sex;

  table chol_status='' All,n='people' pctn='%people'*f=pctfmt./box='cholesterol' 
   style=[pretext='chol_status field'];
   
  
  table bp_status='' All,n='people' pctn='%people'*f=pctfmt./box='BP '
  style=[pretext='bp_status field'];;
   

  table sex='' All,n='people' pctn='%people'*f=pctfmt./box='Gender'
  style=[pretext='sex field'];
run;

Thanks 🙂

Re: multiple one-way freq tables via proc tabulate

Kurt_Bremser — Mon, 04 Feb 2019 10:32:42 GMT

title is a global statement which is executed immediately when encountered in the code.

The proc tabulate code is fetched until a step boundary is encountered, and executed then.

So your code is equivalent to this:

title 'chol_status field';
title 'bp_status field';
title 'sex field';

proc tabulate data=sashelp.heart;
  class chol_status bp_status  sex;

  table chol_status='' All,n='people' pctn='%people'*f=pctfmt./box='cholesterol';

  table bp_status='' All,n='people' pctn='%people'*f=pctfmt./box='BP ';

  table sex='' All,n='people' pctn='%people'*f=pctfmt./box='Gender';
run;

You need to do three separate proc tabulates.

Re: multiple one-way freq tables via proc tabulate

ballardw — Mon, 04 Feb 2019 16:16:09 GMT

"Not working" is awful vague.

Are there errors in the log?: Post the code and log in a code box opened with the {i} to maintain formatting of error messages.

No output? Post any log in a code box.

Unexpected output? Provide input data in the form of data step code pasted into a code box, the actual results and the expected results. Instructions here: https://communities.sas.com/t5/SAS-Communities-Library/How-to-create-a-data-step-version-of-your-dat... will show how to turn an existing SAS data set into data step code that can be pasted into a forum code box using the {i} icon or attached as text to show exactly what you have and that we can test code against.

Since your output does consist of three separate tables I have to guess that your complaint is that you get the LAST defined title for all three tables. That is way the TITLE statement works for any procedure with multiple tables; they all get the same title.

You can use Style= Pretext to place different text before each table

title;/* turn off existing titles*/
proc tabulate data=sashelp.heart;
  class chol_status bp_status  sex;

  table chol_status='' All,n='people' pctn='%people'*f=pctfmt.
   /box='cholesterol' style=[Pretext='chol_status field'];

  table bp_status='' All,n='people' pctn='%people'*f=pctfmt.
   /box='BP ' style=[Pretext='bp_status field'];

  table sex='' All,n='people' pctn='%people'*f=pctfmt.
   /box='Gender' style=[Pretext='sex field'];
run;

Re: multiple one-way freq tables via proc tabulate

Ronein — Sun, 10 Feb 2019 04:28:14 GMT

When I write "not working" and I said that the problem is with titles.

You could run it and see it .

Re: multiple one-way freq tables via proc tabulate

ballardw — Mon, 11 Feb 2019 18:50:51 GMT

@Ronein wrote:

When I write "not working" and I said that the problem is with titles.

You could run it and see it .

Yes, but you did not actually include what the output should look like. So I was guessing at the desired result.