topic Re: Find top & bottom 10% of records by group in SAS Programming

Find top & bottom 10% of records by group

mahibhu — Mon, 11 Feb 2019 12:59:44 GMT

hi need quick help!

if i need to get the top% & bottom 10% by each group.

can you please give me some solution with example.

Thanks Inadvance

Mahendra

Re: Find top & bottom 10% of records by group

ChrisHemedinger — Mon, 11 Feb 2019 13:09:23 GMT

Here's one way, using PROC RANK -- tailor made for problems like this. The RANK procedure can assign ranks by decile (groups=10), so rank=0 is the lowest 10%, and rank=9 is the highest 10%. Here's an example with the CARS data.

proc sort
	data=sashelp.cars
	out=work.sortedcars
	;
	by origin;
run;

proc rank data = work.sortedcars
	groups=10
	ties=mean
	out=top_bottom;
	by origin;
	var msrp;
ranks ranked_msrp ;
run;

title "top 10% in each group";
proc print data=top_bottom;
 var origin make model msrp;
 where ranked_msrp = 9;
 by origin;
run;

title "bottom 10% in each group";
proc print data=top_bottom;
 var origin make model msrp;
 where ranked_msrp = 0;
 by origin;
run;

Re: Find top & bottom 10% of records by group

mkeintz — Mon, 11 Feb 2019 13:14:25 GMT

Take a look at documentation on PROC RANK. You'll probably want to set the GROUPS=10 option.