topic Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference. in SAS Programming

ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Vigneswar — Fri, 01 Feb 2019 10:41:07 GMT

Hi,

I am trying to create a file name Canada_CM_ Jan_28_2019 .

File is basically extracting the Business name with monday's date of the week.

Below is my code,

%let t=%sysfunc(today());
%let monday=%sysfunc(intnx(week.2,&t,0,b),date9.);
%let outputdate=%substr(&monday,3,3)_%substr(&monday,1,2)_%substr(&monday,6);
%put &outputdate;

%let Business = %sysfunc(scan(Canada_all,1,'_'));
%put &Business;

%let file = %qsysfunc(&Business_CM_ &outputdate);

%put &file;

When run the code I am getting the below error,

WARNING: Apparent symbolic reference BUSINESS_CM_ not resolved.
ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Any suggestions.

Thanks,

Vigneswar

Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

RW9 — Fri, 01 Feb 2019 11:00:04 GMT

data _null_;
  want=cats("Canada_CM_",put(month(today()),monname3.),put(day(today(),best.),put(year(today()),best.));
  call symputx('file',want);
run;

Note not tested, but something like that.

Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

karolis_b — Fri, 01 Feb 2019 11:06:00 GMT

Hi!

It tries to resolve Business_CM macro variable, but you haven't declared it. I'm guessing, you are trying to resolve &Business followed by _CM_ and then date. Try code below. I added . after &Business, also I have changed %sysfunc(scan()) to %scan.

%let t=%sysfunc(today());
%let monday=%sysfunc(intnx(week.2,&t,0,b),date9.);
%let outputdate=%substr(&monday,3,3)_%substr(&monday,1,2)_%substr(&monday,6);
%put &outputdate;

%let Business = %scan(Canada_all,1,_);
%put &Business;

%let file = &Business._CM_&outputdate;

%put &file;

- Karolis

Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Vigneswar — Fri, 01 Feb 2019 11:06:27 GMT

%let Business = %sysfunc(scan(Canada_all,1,'_'));

where scan(&output.,1,'_')

This output value is not specific to canada. It is dynamically changing getting resolved by an another macro &output.

Sorry for missing this!

Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Kurt_Bremser — Fri, 01 Feb 2019 11:49:50 GMT

See Maxim 48. Always terminate macro variable references with a dot (&Business.).

Re: ERROR: Function name missing in %SYSFUNC or %QSYSFUNC macro function reference.

Vigneswar — Fri, 01 Feb 2019 11:50:59 GMT

You are right. I missed . while referring Business. It worked now.

Thanks a lot Karolis!