topic Re: Creating datalines with multiple data in one observation in SAS Programming

Creating datalines with multiple data in one observation

JUMMY — Tue, 22 Jan 2019 19:00:59 GMT

Each observation under Y has four values. I tried the following:

data one;
  input X Y;
datalines;
2.5  7.5 9.5 8.0 8.5
5.0  11.0 12.0 9.0 10.0
7.5  11.0 16.0 12.5 14.0
10.0  16.5 14.5 21.5 19.0
;
run;

How do I enter the following data below in SAS using datalines?

X Y

2.5 7.5 9.5 8.0 8.5

5.0 11.0 12.0 9.0 10.0

7.5 11.0 16.0 12.5 14.0

10.0 16.5 14.5 21.5 19.0

Re: Creating datalines with multiple data in one observation

PeterClemmensen — Tue, 22 Jan 2019 19:09:48 GMT

This does not seem like a smart way to store data. You can only define Y like this as a character variable like this

data one;
  input X Y $20.;
  infile datalines dlm=',';
datalines;
2.5,7.5 9.5 8.0 8.5
5.0,11.0 12.0 9.0 10.0
7.5,11.0 16.0 12.5 14.0
10.0,16.5 14.5 21.5 19.0
;
run;

A more proper way of defining the data would be as four numeric variable Y1-Y4 like this

data one;
  input X Y1-Y4;
datalines;
2.5 7.5 9.5 8.0 8.5
5.0 11.0 12.0 9.0 10.0
7.5 11.0 16.0 12.5 14.0
10.0 16.5 14.5 21.5 19.0
;
run;

Re: Creating datalines with multiple data in one observation

ballardw — Tue, 22 Jan 2019 20:18:32 GMT

Or perhaps:

data one;
  input X @;
  do i= 1 to 4;
   input Y @;
   output;
  end;
  drop i;
datalines;
2.5  7.5 9.5 8.0 8.5
5.0  11.0 12.0 9.0 10.0
7.5  11.0 16.0 12.5 14.0
10.0  16.5 14.5 21.5 19.0
;
run;

Which creates 4 pairs of x, y values with the same X.