topic create the interval from Today's 2pm to the next day's 2 pm. in SAS Programming

create the interval from Today's 2pm to the next day's 2 pm.

asch1234 — Tue, 15 Jan 2019 05:56:49 GMT

I want to create the interval from Today's 2pm to the next day's 2 pm.

And put the last price in to the interval.

date	time	price
20071025	13:57:30	100.312
20071025	15:37:30	100.064
20071026	11:50:04	100.05
20071026	17:18:09	99.992
20071027	17:12:09	99.998

I try use

TIME30=intnx("Hour24.15", time, 0, "E");

But, I like to get the following dataset from the raw dataset.

20071025 13:59:59 100.312

20071026 13:59:59 100.05

20071027 13:59:59 99.992

20071028 13:59:59 99.998

Re: create the interval from Today's 2pm to the next day's 2 pm.

mkeintz — Tue, 15 Jan 2019 06:31:59 GMT

'hour24.15' is right, but you need to apply it to datetime values, not just time values:

data have;
input date yymmdd8. time :time8.0 price;
format date date9. time time8.0;
datalines; 
20071025 13:57:30 100.312
20071025 15:37:30 100.064
20071026 11:50:04 100.05
20071026 17:18:09 99.992
20071027 17:12:09 99.998
run;


data need/view=need;
  set have;
  index_dt=dhms(date,0,0,0)+time; 
  index_dt=intnx('hour24.15',index_dt,0,'e'); 
  format index_dt datetime20.;
run;

data want (drop=index_dt); 
  set need;
  by index_dt;
  if last.index_dt;
  time=timepart(index_dt);
run;