topic Re: labeling more than 400 variables in SAS Programming

labeling more than 400 variables

akki39k — Mon, 14 Jan 2019 06:42:55 GMT

I have tow excel files.

First one contain the original data which contains data from a company

The second file contains all the labels for the above data headers

My question is that how to label all the headers present in the first file according to the labels present in second file. There are more than 400 header in first file which are needed to properly labeled by the labels present in second file

Re: labeling more than 400 variables

Kurt_Bremser — Mon, 14 Jan 2019 10:10:26 GMT

How do they correspond to each other? By position in the spreadsheet only, or do you have name/label pairs?

Re: labeling more than 400 variables

akki39k — Mon, 14 Jan 2019 13:00:38 GMT

I have name label pairs in the second file like

Name of the header in A1 and corresponding label in B2 of spreadsheet

Re: labeling more than 400 variables

PaigeMiller — Mon, 14 Jan 2019 13:06:17 GMT

@akki39k wrote:

I have name label pairs in the second file like

Name of the header in A1 and corresponding label in B2 of spreadsheet

Is this a typographical error? Should it say: name of the header in A2 and label in B2?

Can you show us a few records of these label pairs?

Re: labeling more than 400 variables

Kurt_Bremser — Mon, 14 Jan 2019 13:15:21 GMT

Let's make up some data that more or less resembles what you imported from Excel:

Data from the first spreadsheet, with two columns:

data mydata;
input var1 $ var2;
cards;
x 1
y 2
z 3
;
run;

Data from the second spreadsheet, with two lines:

data headers;
infile cards dlm=',';
input col_a $ col_b :$64.;
cards;
var1,this is the label for var1
var2,this is the label for var2
;
run;

Now let's use the second dataset to dynamically create a proc datasets step that sets the labels:

data _null_;
set headers end=eof;
if _n_ = 1 then call execute('proc datasets noprint; modify mydata; label ');
call execute(col_a !! ' = "' !! strip(col_b) !! '" ');
if eof then call execute('; run; quit;');
run;

and print the result:

proc print data=mydata noobs label;
run;

This is what we get:

 this is      this is
the label    the label
for var1      for var2

    x            1    
    y            2    
    z            3

Re: labeling more than 400 variables

akki39k — Mon, 14 Jan 2019 14:23:37 GMT

My second file looks like this

Re: labeling more than 400 variables

Kurt_Bremser — Mon, 14 Jan 2019 14:28:01 GMT

So you just have to use variable in place of col_a and label in place of col_b.

Re: labeling more than 400 variables

akki39k — Mon, 14 Jan 2019 14:39:42 GMT

Thank you for looking into my concern and providing the solution